libv4l: import from upstream

The unmodified version works for us, so import it from upstream Gentoo
rather than having our own copy in chromiumos-overlay/.

BUG=chromium-os:25177
TEST=`emerge-x86-alex libv4l` still works

Change-Id: I64744d1f820cc06062b3376176db292aeb82793c
Reviewed-on: https://gerrit.chromium.org/gerrit/21340
Commit-Ready: Mike Frysinger <vapier@chromium.org>
Reviewed-by: Mike Frysinger <vapier@chromium.org>
Tested-by: Mike Frysinger <vapier@chromium.org>

sdk_container/src/third_party/portage-stable/media-libs/libv4l/libv4l-0.8.5.ebuild

@@ -0,0 +1,43 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-libs/libv4l/libv4l-0.8.5.ebuild,v 1.8 2012/01/13 16:07:46 vapier Exp $
+
+EAPI=4
+inherit linux-info multilib toolchain-funcs
+
+MY_P=v4l-utils-${PV}
+
+DESCRIPTION="Separate libraries ebuild from upstream v4l-utils package"
+HOMEPAGE="http://git.linuxtv.org/v4l-utils.git"
+SRC_URI="http://linuxtv.org/downloads/v4l-utils/${MY_P}.tar.bz2"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="alpha amd64 arm hppa ia64 ppc ppc64 sparc x86 ~amd64-linux ~x86-linux"
+IUSE=""
+
+RDEPEND="virtual/jpeg"
+DEPEND="${RDEPEND}
+	>=sys-kernel/linux-headers-2.6.30-r1"
+
+S=${WORKDIR}/${MY_P}
+
+CONFIG_CHECK="~SHMEM"
+
+src_prepare() {
+	sed -i \
+		-e "/^PREFIX =/s:=.*:= ${EPREFIX}/usr:" \
+		-e "/^LIBDIR =/s:/lib:/$(get_libdir):" \
+		-e "/^CFLAGS :=/d" \
+		Make.rules || die
+	tc-export CC
+}
+
+src_compile() {
+	emake -C lib
+}
+
+src_install() {
+	emake -C lib DESTDIR="${D}" install
+	dodoc ChangeLog README.lib* TODO
+}