sys-fs/btrfs-progs: Add from gentoo

It's from gentoo commit 638e02f491a1e37f2af31523490f00f8a118419d.

sdk_container/src/third_party/coreos-overlay/sys-fs/btrfs-progs/Manifest

@@ -0,0 +1 @@
+DIST btrfs-progs-v5.10.1.tar.xz 2204164 BLAKE2B ed83729754f9abd22d4d2e7ae9a7e90e80be9b63d49a4a9692e20e5939467dbd864834b71495661e1c7a1fca89e253a62fbda37f1d01d2eadecb13f5904f0dd0 SHA512 32e5b8bda1863e34613802db91946f240b2cde21288ff8f95c1807e7afd0a67c5a704aa4d2bc0d7b1ca094de6831adbfec83fe61f74e1caf6d1975be7d972f2d

sdk_container/src/third_party/coreos-overlay/sys-fs/btrfs-progs/btrfs-progs-5.10.1-r1.ebuild

@@ -0,0 +1,127 @@
+# Copyright 2008-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{8..9} )
+
+inherit bash-completion-r1 python-single-r1
+
+libbtrfs_soname=0
+
+if [[ ${PV} != 9999 ]]; then
+	MY_PV="v${PV/_/-}"
+	[[ "${PV}" = *_rc* ]] || \
+	KEYWORDS="~alpha amd64 arm arm64 ~ia64 ~mips ppc ppc64 ~riscv ~sparc x86"
+	SRC_URI="https://www.kernel.org/pub/linux/kernel/people/kdave/${PN}/${PN}-${MY_PV}.tar.xz"
+	S="${WORKDIR}/${PN}-${MY_PV}"
+else
+	WANT_LIBTOOL=none
+	inherit autotools git-r3
+	EGIT_REPO_URI="https://github.com/kdave/btrfs-progs.git"
+	EGIT_BRANCH="devel"
+fi
+
+DESCRIPTION="Btrfs filesystem utilities"
+HOMEPAGE="https://btrfs.wiki.kernel.org"
+
+LICENSE="GPL-2"
+SLOT="0/${libbtrfs_soname}"
+IUSE="+convert doc python reiserfs static static-libs +zstd"
+
+RESTRICT=test # tries to mount repared filesystems
+
+RDEPEND="
+	dev-libs/lzo:2=
+	sys-apps/util-linux:0=[static-libs(+)?]
+	sys-libs/zlib:0=
+	convert? (
+		sys-fs/e2fsprogs:=
+		reiserfs? (
+			>=sys-fs/reiserfsprogs-3.6.27
+		)
+	)
+	python? ( ${PYTHON_DEPS} )
+	zstd? ( app-arch/zstd:0= )
+"
+DEPEND="${RDEPEND}
+	convert? ( sys-apps/acl )
+	python? (
+		$(python_gen_cond_dep '
+			dev-python/setuptools[${PYTHON_USEDEP}]
+		')
+	)
+	static? (
+		dev-libs/lzo:2[static-libs(+)]
+		sys-apps/util-linux:0[static-libs(+)]
+		sys-libs/zlib:0[static-libs(+)]
+		convert? (
+			sys-fs/e2fsprogs[static-libs(+)]
+			reiserfs? (
+				>=sys-fs/reiserfsprogs-3.6.27[static-libs(+)]
+			)
+		)
+		zstd? ( app-arch/zstd:0[static-libs(+)] )
+	)
+"
+BDEPEND="
+	doc? (
+		|| ( >=app-text/asciidoc-8.6.0 dev-ruby/asciidoctor )
+		app-text/docbook-xml-dtd:4.5
+		app-text/xmlto
+	)
+"
+
+if [[ ${PV} == 9999 ]]; then
+	DEPEND+=" sys-devel/gnuconfig"
+fi
+
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+
+pkg_setup() {
+	use python && python-single-r1_pkg_setup
+}
+
+src_prepare() {
+	default
+	if [[ ${PV} == 9999 ]]; then
+		AT_M4DIR=m4 eautoreconf
+		mkdir config || die
+		local automakedir="$(autotools_run_tool --at-output automake --print-libdir)"
+		[[ -e ${automakedir} ]] || die "Could not locate automake directory"
+		ln -s "${automakedir}"/install-sh config/install-sh || die
+		ln -s "${EPREFIX}"/usr/share/gnuconfig/config.guess config/config.guess || die
+		ln -s "${EPREFIX}"/usr/share/gnuconfig/config.sub config/config.sub || die
+	fi
+}
+
+src_configure() {
+	local myeconfargs=(
+		--bindir="${EPREFIX}"/sbin
+		$(use_enable convert)
+		$(use_enable doc documentation)
+		$(use_enable elibc_glibc backtrace)
+		$(use_enable python)
+		$(use_enable static-libs static)
+		$(use_enable zstd)
+		--with-convert=ext2$(usex reiserfs ',reiserfs' '')
+	)
+	econf "${myeconfargs[@]}"
+}
+
+src_compile() {
+	emake V=1 all $(usev static)
+}
+
+src_install() {
+	local makeargs=(
+		$(usex python install_python '')
+		$(usex static install-static '')
+	)
+	emake V=1 DESTDIR="${D}" install "${makeargs[@]}"
+	newbashcomp btrfs-completion btrfs
+	use python && python_optimize
+
+	# install prebuilt subset of manuals
+	use doc || doman Documentation/*.[58]
+}

sdk_container/src/third_party/coreos-overlay/sys-fs/btrfs-progs/metadata.xml

@@ -0,0 +1,13 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+  <maintainer type="project">
+    <email>base-system@gentoo.org</email>
+    <name>Gentoo Base System</name>
+  </maintainer>
+  <use>
+    <flag name="convert">Build ext2 conversion utility (btrfs-convert)</flag>
+    <flag name="reiserfs">Enable reiserfs support in btrfs-convert tool.</flag>
+    <flag name="static">Build static binaries in addition to the dynamic ones</flag>
+  </use>
+</pkgmetadata>