From ea06ca8bb6a691bb1d8da15f8d8dce13c370abbf Mon Sep 17 00:00:00 2001
From: Flatcar Buildbot <buildbot@flatcar-linux.org>
Date: Mon, 1 Jul 2024 07:13:19 +0000
Subject: [PATCH] dev-libs/libdnet: Sync with Gentoo

It's from Gentoo commit 17b0683649b79143c2173144887ae0743abdbe1e.
---
 .../dev-libs/libdnet/libdnet-1.18.0-r1.ebuild | 98 +++++++++++++++++++
 .../dev-libs/libdnet/libdnet-1.18.0.ebuild    |  2 +-
 2 files changed, 99 insertions(+), 1 deletion(-)
 create mode 100644 sdk_container/src/third_party/portage-stable/dev-libs/libdnet/libdnet-1.18.0-r1.ebuild

diff --git a/sdk_container/src/third_party/portage-stable/dev-libs/libdnet/libdnet-1.18.0-r1.ebuild b/sdk_container/src/third_party/portage-stable/dev-libs/libdnet/libdnet-1.18.0-r1.ebuild
new file mode 100644
index 0000000000..b7c86a6585
--- /dev/null
+++ b/sdk_container/src/third_party/portage-stable/dev-libs/libdnet/libdnet-1.18.0-r1.ebuild
@@ -0,0 +1,98 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..12} )
+DISTUTILS_EXT=1
+DISTUTILS_OPTIONAL=1
+DISTUTILS_USE_PEP517=setuptools
+
+inherit autotools distutils-r1
+
+DESCRIPTION="Simplified, portable interface to several low-level networking routines"
+HOMEPAGE="https://github.com/ofalk/libdnet"
+SRC_URI="https://github.com/ofalk/${PN}/archive/${P}.tar.gz"
+S="${WORKDIR}/${PN}-${P}"
+
+LICENSE="LGPL-2"
+SLOT="0"
+KEYWORDS="~alpha amd64 arm ~arm64 ~hppa ~ia64 ~mips ppc ppc64 ~riscv sparc x86"
+IUSE="python test"
+RESTRICT="!test? ( test )"
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+
+DEPEND="
+	dev-libs/libbsd
+	python? ( ${PYTHON_DEPS} )
+"
+RDEPEND="${DEPEND}"
+BDEPEND="
+	python? (
+		${DISTUTILS_DEPS}
+		dev-python/cython[${PYTHON_USEDEP}]
+	)
+	test? ( dev-libs/check )
+"
+
+DOCS=( README.md THANKS )
+
+src_prepare() {
+	default
+
+	sed -i \
+		-e 's/libcheck.a/libcheck.so/g' \
+		configure.ac || die
+	sed -i \
+		-e "s/lib\/libcheck/$(get_libdir)\/libcheck/g" \
+		configure.ac || die
+	sed -i \
+		-e 's|-L$libdir ||g' \
+		dnet-config.in || die
+	sed -i \
+		-e '/^SUBDIRS/s|python||g' \
+		Makefile.am || die
+
+	# Stale e.g. pkg-config macros w/ bashisms
+	rm aclocal.m4 {config,m4}/libtool.m4 || die
+
+	AT_M4DIR="config" eautoreconf
+
+	if use python; then
+		cd python || die
+		distutils-r1_src_prepare
+	fi
+}
+
+src_configure() {
+	econf \
+		$(use_with python) \
+		$(use_enable test check)
+}
+
+src_compile() {
+	default
+
+	if use python; then
+		cd python || die
+		distutils-r1_src_compile
+	fi
+}
+
+src_test() {
+	# https://bugs.gentoo.org/778797#c4
+	# check_ip needs privileges and check_fw can't work on Linux
+	emake check XFAIL_TESTS="check_fw check_ip"
+}
+
+src_install() {
+	default
+
+	if use python; then
+		cd python || die
+		unset DOCS
+		distutils-r1_src_install
+	fi
+
+	find "${ED}" -name '*.la' -delete || die
+}
diff --git a/sdk_container/src/third_party/portage-stable/dev-libs/libdnet/libdnet-1.18.0.ebuild b/sdk_container/src/third_party/portage-stable/dev-libs/libdnet/libdnet-1.18.0.ebuild
index fd47d46e01..06d3ec2171 100644
--- a/sdk_container/src/third_party/portage-stable/dev-libs/libdnet/libdnet-1.18.0.ebuild
+++ b/sdk_container/src/third_party/portage-stable/dev-libs/libdnet/libdnet-1.18.0.ebuild
@@ -15,7 +15,7 @@ S="${WORKDIR}/${PN}-${P}"
 
 LICENSE="LGPL-2"
 SLOT="0"
-KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~riscv ~sparc ~x86"
+KEYWORDS="~alpha amd64 arm ~arm64 ~hppa ~ia64 ~mips ppc ppc64 ~riscv sparc x86"
 IUSE="python test"
 RESTRICT="!test? ( test )"
 REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"