dev-util/catalyst: Copy from Gentoo

sdk_container/src/third_party/coreos-overlay/dev-util/catalyst/Manifest

@@ -0,0 +1 @@
+DIST catalyst-3.0.14.tar.bz2 621178 BLAKE2B 3fa87125f14661bb77432267f03c0966eff8f71f4ef334ce0a14218f7557dee270840afb79b6735a149851ed44b1ea2f6cf59d8274d74e049246d89874aa484b SHA512 938a63a83458fa5a26a4b4e62d18086ed813aec5638a9dd363ba553cb7aeb337c3b8ba0768f3b5a658aa54f2f375a7fe067279c739073d2420c3ad3a42830830

sdk_container/src/third_party/coreos-overlay/dev-util/catalyst/catalyst-3.0.14.ebuild

@@ -0,0 +1,69 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+if [[ ${PV} == *9999* ]]; then
+	SRC_ECLASS="git-r3"
+	EGIT_REPO_URI="https://anongit.gentoo.org/git/proj/catalyst.git"
+	EGIT_BRANCH="master"
+else
+	SRC_URI="https://gitweb.gentoo.org/proj/catalyst.git/snapshot/${P}.tar.bz2"
+	KEYWORDS="~alpha amd64 arm arm64 hppa ~ia64 ~mips ppc ppc64 ~riscv s390 sparc x86"
+fi
+
+PYTHON_COMPAT=( python3_{6,7,8} )
+DISTUTILS_USE_SETUPTOOLS=no
+
+inherit distutils-r1 ${SRC_ECLASS}
+
+DESCRIPTION="Release metatool used for creating releases based on Gentoo Linux"
+HOMEPAGE="https://wiki.gentoo.org/wiki/Catalyst"
+
+LICENSE="GPL-2+"
+SLOT="0"
+IUSE="ccache doc +iso kernel_linux system-bootloader"
+
+DEPEND="
+	app-text/asciidoc
+	>=dev-python/snakeoil-0.6.5[${PYTHON_USEDEP}]
+"
+RDEPEND="
+	>=dev-python/snakeoil-0.6.5[${PYTHON_USEDEP}]
+	>=dev-python/pydecomp-0.3[${PYTHON_USEDEP}]
+	app-arch/lbzip2
+	app-crypt/shash
+	sys-fs/dosfstools
+	!kernel_FreeBSD? ( || ( app-arch/tar[xattr] app-arch/libarchive[xattr] ) )
+	kernel_FreeBSD? ( app-arch/libarchive[xattr] )
+	amd64? ( >=sys-boot/syslinux-3.72 )
+	x86? ( >=sys-boot/syslinux-3.72 )
+	ccache? ( dev-util/ccache )
+	iso? ( virtual/cdrtools )
+	kernel_linux? ( app-misc/zisofs-tools >=sys-fs/squashfs-tools-2.1 )
+"
+PDEPEND="system-bootloader? ( >=sys-apps/memtest86+-5.01-r4
+				sys-boot/grub:2
+				amd64? ( sys-boot/grub[grub_platforms_efi-32,grub_platforms_efi-64] )
+				x86? ( sys-boot/grub[grub_platforms_efi-32] )
+				sys-boot/syslinux
+				sys-boot/shim )"
+
+python_prepare_all() {
+	python_setup
+	echo VERSION="${PV}" "${PYTHON}" setup.py set_version
+	VERSION="${PV}" "${PYTHON}" setup.py set_version || die
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	# build the man pages and docs
+	emake
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+	if use doc; then
+		dodoc files/HOWTO.html files/docbook-xsl.css
+	fi
+}

sdk_container/src/third_party/coreos-overlay/dev-util/catalyst/catalyst-9999.ebuild

@@ -0,0 +1,107 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+if [[ ${PV} == *9999* ]]; then
+	SRC_ECLASS="git-r3"
+	EGIT_REPO_URI="https://anongit.gentoo.org/git/proj/catalyst.git"
+	EGIT_BRANCH="master"
+else
+	SRC_URI="https://gitweb.gentoo.org/proj/catalyst.git/snapshot/${P}.tar.bz2"
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+fi
+
+PYTHON_COMPAT=( python3_{7,8} )
+DISTUTILS_USE_SETUPTOOLS=no
+
+inherit distutils-r1 linux-info optfeature ${SRC_ECLASS}
+
+DESCRIPTION="Release metatool used for creating releases based on Gentoo Linux"
+HOMEPAGE="https://wiki.gentoo.org/wiki/Catalyst"
+
+LICENSE="GPL-2+"
+SLOT="0"
+IUSE="doc +iso"
+
+BDEPEND="
+	app-text/asciidoc
+"
+DEPEND="
+	sys-apps/portage[${PYTHON_USEDEP}]
+	>=dev-python/snakeoil-0.6.5[${PYTHON_USEDEP}]
+	dev-python/toml[${PYTHON_USEDEP}]
+"
+RDEPEND="
+	${DEPEND}
+	>=dev-python/pydecomp-0.3[${PYTHON_USEDEP}]
+	app-arch/lbzip2
+	app-arch/pixz
+	app-arch/tar[xattr]
+	dev-vcs/git
+	sys-fs/dosfstools
+	sys-fs/squashfs-tools-ng
+
+	iso? (
+		virtual/cdrtools
+
+		amd64? (
+			sys-boot/grub[grub_platforms_efi-32,grub_platforms_efi-64]
+		)
+		alpha? (
+			dev-libs/libisoburn
+		)
+		ia64?  (
+			dev-libs/libisoburn
+			sys-boot/grub[grub_platforms_efi-64]
+			sys-fs/mtools
+		)
+		ppc?   (
+			dev-libs/libisoburn
+			sys-boot/grub:2[grub_platforms_ieee1275]
+		)
+		ppc64? (
+			dev-libs/libisoburn
+			sys-boot/grub:2[grub_platforms_ieee1275]
+		)
+		sparc? (
+			dev-libs/libisoburn
+			sys-boot/grub:2[grub_platforms_ieee1275]
+		)
+		x86?   (
+			sys-boot/grub[grub_platforms_efi-32]
+		)
+	)
+"
+
+pkg_setup() {
+	CONFIG_CHECK="~UTS_NS ~IPC_NS"
+	linux-info_pkg_setup
+}
+
+python_prepare_all() {
+	python_setup
+	echo VERSION="${PV}" "${PYTHON}" setup.py set_version
+	VERSION="${PV}" "${PYTHON}" setup.py set_version || die
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	# build the man pages and docs
+	emake
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+	if use doc; then
+		dodoc files/HOWTO.html files/docbook-xsl.css
+	fi
+}
+
+pkg_postinst() {
+	if [[ -z ${REPLACING_VERSIONS} ]]; then
+		elog
+		elog "You may consider installing the following optional packages:"
+		optfeature "ccache support" dev-util/ccache
+	fi
+}

sdk_container/src/third_party/coreos-overlay/dev-util/catalyst/metadata.xml

@@ -0,0 +1,16 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+  <maintainer type="project">
+    <email>catalyst@gentoo.org</email>
+  </maintainer>
+  <maintainer type="project">
+    <email>livecd@gentoo.org</email>
+    <name>Gentoo LiveCD Project</name>
+  </maintainer>
+  <use>
+    <flag name="ccache">Enables ccache support</flag>
+    <flag name="iso">Pulls in the depends for building iso images</flag>
+    <flag name="system-bootloader">Pulls in the depends needed to setup livecd bootloader from the host system rather than using a cdtar</flag>
+  </use>
+</pkgmetadata>