diff --git a/sdk_container/src/third_party/portage-stable/dev-python/backports-tarfile/Manifest b/sdk_container/src/third_party/portage-stable/dev-python/backports-tarfile/Manifest
new file mode 100644
index 0000000000..11d1ddacd2
--- /dev/null
+++ b/sdk_container/src/third_party/portage-stable/dev-python/backports-tarfile/Manifest
@@ -0,0 +1 @@
+DIST backports_tarfile-1.2.0.tar.gz 86406 BLAKE2B 20ba5dd91c609b6d7a32b8d489bae5f0d29af83d86c187a8b73e95e3fee034a07469fdfd90fc6c6e96b532b2acbf37ba9e01bdae019ca148d3a668762599fa6d SHA512 8f57526e9aabf7f778e876dab06dd7a476316bb02e9eadd703da3ba74f3b8b0c12338a32fbcb033d477a1a1ff115653a2292b730bfded208c9efb21506bc23d4
diff --git a/sdk_container/src/third_party/portage-stable/dev-python/backports-tarfile/backports-tarfile-1.2.0.ebuild b/sdk_container/src/third_party/portage-stable/dev-python/backports-tarfile/backports-tarfile-1.2.0.ebuild
new file mode 100644
index 0000000000..1f0459fd0c
--- /dev/null
+++ b/sdk_container/src/third_party/portage-stable/dev-python/backports-tarfile/backports-tarfile-1.2.0.ebuild
@@ -0,0 +1,46 @@
+# Copyright 2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+# please keep this ebuild at EAPI 8 -- sys-apps/portage dep
+EAPI=8
+
+DISTUTILS_USE_PEP517=flit
+PYPI_PN=${PN/-/.}
+# This is a backport from Python 3.12.
+PYTHON_COMPAT=( pypy3 python3_{10..11} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Backport of CPython tarfile module (from Python 3.12)"
+HOMEPAGE="
+	https://github.com/jaraco/backports.tarfile/
+	https://pypi.org/project/backports.tarfile/
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha amd64 arm arm64 hppa ~ia64 ~loong ~m68k ~mips ppc ppc64 ~riscv ~s390 sparc x86"
+
+BDEPEND="
+	test? (
+		dev-python/jaraco-test[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+src_configure() {
+	grep -q 'build-backend = "setuptools' pyproject.toml ||
+		die "Upstream changed build-backend, recheck"
+	# write a custom pyproject.toml to ease setuptools bootstrap
+	cat > pyproject.toml <<-EOF || die
+		[build-system]
+		requires = ["flit_core >=3.2,<4"]
+		build-backend = "flit_core.buildapi"
+
+		[project]
+		name = "backports.tarfile"
+		version = "${PV}"
+		description = "Backport of CPython tarfile module"
+	EOF
+}
diff --git a/sdk_container/src/third_party/portage-stable/dev-python/backports-tarfile/metadata.xml b/sdk_container/src/third_party/portage-stable/dev-python/backports-tarfile/metadata.xml
new file mode 100644
index 0000000000..63138bedd1
--- /dev/null
+++ b/sdk_container/src/third_party/portage-stable/dev-python/backports-tarfile/metadata.xml
@@ -0,0 +1,12 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="project">
+		<email>python@gentoo.org</email>
+	</maintainer>
+	<stabilize-allarches/>
+	<upstream>
+		<remote-id type="github">jaraco/backports.tarfile</remote-id>
+		<remote-id type="pypi">backports.tarfile</remote-id>
+	</upstream>
+</pkgmetadata>