From c752baf538a0c1b08ff89991b6aa2fe79b8c6a59 Mon Sep 17 00:00:00 2001
From: Krzesimir Nowak <knowak@microsoft.com>
Date: Fri, 2 Aug 2024 17:11:32 +0200
Subject: [PATCH] dev-python/requests: Add from Gentoo

It's from Gentoo commit 241df8932bc30058b73a03d2e6605c70f5fdca9a.
---
 .../dev-python/requests/Manifest              |  1 +
 .../dev-python/requests/metadata.xml          | 20 +++++
 .../requests/requests-2.32.3.ebuild           | 82 +++++++++++++++++++
 3 files changed, 103 insertions(+)
 create mode 100644 sdk_container/src/third_party/portage-stable/dev-python/requests/Manifest
 create mode 100644 sdk_container/src/third_party/portage-stable/dev-python/requests/metadata.xml
 create mode 100644 sdk_container/src/third_party/portage-stable/dev-python/requests/requests-2.32.3.ebuild

diff --git a/sdk_container/src/third_party/portage-stable/dev-python/requests/Manifest b/sdk_container/src/third_party/portage-stable/dev-python/requests/Manifest
new file mode 100644
index 0000000000..efbbda4ca0
--- /dev/null
+++ b/sdk_container/src/third_party/portage-stable/dev-python/requests/Manifest
@@ -0,0 +1 @@
+DIST requests-2.32.3.tar.gz 131218 BLAKE2B c36bd80e0544e83b80c001e6bfdde7b8552e65b888d44d781f95d5a6302dd34dfd4368e18dbfeab3a014d7170946c502e3bf3a6dbd027a60a2f0f535c674d75c SHA512 20d413597ff4803a62156ada25ef2e8a5edd0d4dbf7d79cc7fcd88d51a76e019a7dacf41d7c3d546306f37c506ede68f16b9afea57c918db64e702382b1ae420
diff --git a/sdk_container/src/third_party/portage-stable/dev-python/requests/metadata.xml b/sdk_container/src/third_party/portage-stable/dev-python/requests/metadata.xml
new file mode 100644
index 0000000000..da82b014f5
--- /dev/null
+++ b/sdk_container/src/third_party/portage-stable/dev-python/requests/metadata.xml
@@ -0,0 +1,20 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+  <maintainer type="project">
+    <email>python@gentoo.org</email>
+    <name>Python</name>
+  </maintainer>
+  <longdescription lang="en">
+    Most existing Python modules for sending HTTP requests are extremely verbose and
+    cumbersome. Python’s built-in urllib2 module provides most of the HTTP
+    capabilities you should need, but the API is thoroughly broken. This library is
+    designed to make HTTP requests easy for developers.
+  </longdescription>
+  <stabilize-allarches/>
+  <upstream>
+    <remote-id type="github">psf/requests</remote-id>
+    <remote-id type="pypi">requests</remote-id>
+    <remote-id type="cpe">cpe:/a:python-requests:requests</remote-id>
+  </upstream>
+</pkgmetadata>
diff --git a/sdk_container/src/third_party/portage-stable/dev-python/requests/requests-2.32.3.ebuild b/sdk_container/src/third_party/portage-stable/dev-python/requests/requests-2.32.3.ebuild
new file mode 100644
index 0000000000..a59ea6ebea
--- /dev/null
+++ b/sdk_container/src/third_party/portage-stable/dev-python/requests/requests-2.32.3.ebuild
@@ -0,0 +1,82 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+# please keep this ebuild at EAPI 8 -- sys-apps/portage dep
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..13} pypy3 )
+PYTHON_REQ_USE="threads(+)"
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="HTTP library for human beings"
+HOMEPAGE="
+	https://requests.readthedocs.io/
+	https://github.com/psf/requests/
+	https://pypi.org/project/requests/
+"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~alpha amd64 arm arm64 hppa ~ia64 ~loong ~m68k ~mips ppc ppc64 ~riscv ~s390 sparc x86 ~arm64-macos ~x64-macos"
+IUSE="socks5 test-rust"
+
+RDEPEND="
+	>=dev-python/certifi-2017.4.17[${PYTHON_USEDEP}]
+	<dev-python/charset-normalizer-4[${PYTHON_USEDEP}]
+	<dev-python/idna-4[${PYTHON_USEDEP}]
+	<dev-python/urllib3-3[${PYTHON_USEDEP}]
+	socks5? ( >=dev-python/PySocks-1.5.6[${PYTHON_USEDEP}] )
+"
+
+BDEPEND="
+	test? (
+		>=dev-python/pytest-httpbin-2.0.0[${PYTHON_USEDEP}]
+		dev-python/pytest-mock[${PYTHON_USEDEP}]
+		>=dev-python/PySocks-1.5.6[${PYTHON_USEDEP}]
+		test-rust? (
+			dev-python/trustme[${PYTHON_USEDEP}]
+		)
+	)
+"
+
+distutils_enable_tests pytest
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# Internet (doctests)
+		requests/__init__.py::requests
+		requests/api.py::requests.api.request
+		requests/models.py::requests.models.PreparedRequest
+		requests/sessions.py::requests.sessions.Session
+		# require IPv4 interface in 10.* range
+		tests/test_requests.py::TestTimeout::test_connect_timeout
+		tests/test_requests.py::TestTimeout::test_total_timeout_connect
+		# TODO: openssl?
+		tests/test_requests.py::TestRequests::test_pyopenssl_redirect
+		# flask-2
+		tests/test_requests.py::TestRequests::test_cookie_sent_on_redirect
+		tests/test_requests.py::TestRequests::test_cookie_removed_on_expire
+		tests/test_requests.py::TestPreparingURLs::test_redirecting_to_bad_url
+	)
+
+	case ${EPYTHON} in
+		python3.13)
+			;&
+		python3.12)
+			EPYTEST_DESELECT+=(
+				# different repr()
+				requests/utils.py::requests.utils.from_key_val_list
+			)
+			;;
+	esac
+
+	if ! has_version "dev-python/trustme[${PYTHON_USEDEP}]"; then
+		EPYTEST_DESELECT+=(
+			tests/test_requests.py::TestRequests::test_https_warnings
+		)
+	fi
+
+	epytest
+}