diff --git a/sdk_container/src/third_party/portage-stable/dev-libs/libgudev/Manifest b/sdk_container/src/third_party/portage-stable/dev-libs/libgudev/Manifest
new file mode 100644
index 0000000000..4b42a0c9e8
--- /dev/null
+++ b/sdk_container/src/third_party/portage-stable/dev-libs/libgudev/Manifest
@@ -0,0 +1 @@
+DIST libgudev-238.tar.xz 30548 BLAKE2B 386491e78c82081e89dad897d16ea6733430a67db3f75f2d9fdee5474b074ad6fede9f08e429f4eb6feaa9bbbb982d9d039db738aac5b5ce0ffac2d3a19430d4 SHA512 684061b4fc64a6ea3dd1ac34835279330c7eb2728fad6e3a9d34c0d501be3103d0f96c6d6866c8e257a0027e4f78a6314cb8ba81cda5ddf42ee9ea1a576ec5dc
diff --git a/sdk_container/src/third_party/portage-stable/dev-libs/libgudev/libgudev-238-r1.ebuild b/sdk_container/src/third_party/portage-stable/dev-libs/libgudev/libgudev-238-r1.ebuild
new file mode 100644
index 0000000000..3d1e028885
--- /dev/null
+++ b/sdk_container/src/third_party/portage-stable/dev-libs/libgudev/libgudev-238-r1.ebuild
@@ -0,0 +1,47 @@
+# Copyright 2015-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit meson-multilib
+
+DESCRIPTION="GObject bindings for libudev"
+HOMEPAGE="https://wiki.gnome.org/Projects/libgudev"
+SRC_URI="https://download.gnome.org/sources/libgudev/${PV}/${P}.tar.xz"
+
+LICENSE="LGPL-2.1+"
+SLOT="0/0"
+KEYWORDS="~alpha amd64 arm arm64 ~hppa ~ia64 ~loong ~mips ppc ppc64 ~riscv ~s390 sparc x86"
+IUSE="introspection test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	>=dev-libs/glib-2.38.0:2[${MULTILIB_USEDEP}]
+	>=virtual/libudev-251:=[sticky-tags(+),${MULTILIB_USEDEP}]
+	introspection? ( >=dev-libs/gobject-introspection-1.31.1 )
+"
+DEPEND="${RDEPEND}
+	test? ( dev-util/umockdev[${MULTILIB_USEDEP}] )
+"
+BDEPEND="
+	dev-util/glib-utils
+	virtual/pkgconfig
+"
+
+multilib_src_configure() {
+	local emesonargs=(
+		$(meson_native_use_feature introspection)
+		-Dgtk_doc=false
+		$(meson_feature test tests)
+		-Dvapi=disabled
+	)
+	meson_src_configure
+}
+
+src_test() {
+	# libsandbox interferes somehow.
+	# There are no access violations, but tests fail.
+	# https://bugs.gentoo.org/805449
+	local -x SANDBOX_ON=0
+	meson-multilib_src_test
+}
diff --git a/sdk_container/src/third_party/portage-stable/dev-libs/libgudev/metadata.xml b/sdk_container/src/third_party/portage-stable/dev-libs/libgudev/metadata.xml
new file mode 100644
index 0000000000..3631e95872
--- /dev/null
+++ b/sdk_container/src/third_party/portage-stable/dev-libs/libgudev/metadata.xml
@@ -0,0 +1,14 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+  <maintainer type="project">
+    <email>gnome@gentoo.org</email>
+    <name>Gentoo GNOME Desktop</name>
+  </maintainer>
+  <maintainer type="project">
+    <email>systemd@gentoo.org</email>
+  </maintainer>
+  <upstream>
+    <remote-id type="gnome-gitlab">GNOME/libgudev</remote-id>
+  </upstream>
+</pkgmetadata>