sys-apps/diffutils: Sync with Gentoo

It's from Gentoo commit 863606e6820b046146129c7ede84d1c73f198e41.

sdk_container/src/third_party/portage-stable/sys-apps/diffutils/Manifest

@@ -1,2 +1,4 @@
+DIST diffutils-3.10.242-d65b.tar.xz 1924516 BLAKE2B 3d4a2928b0c9462d1cd570d31b5d8ba32f3c3db23c2f96aca53c55a5d0738ee38ebd412138247313e7dc540284c2243ab49bffd23ed7eb320cef39118f195a2a SHA512 ad27490d59e77f5f6ca4d3a7d88d0ccbc1727aeded2427fd3bf7d5ecf478f182ae24938dec30f0eba9524cae771aac732ad26193a9a3f5356ab204152fa35423
+DIST diffutils-3.10.242-d65b.tar.xz.sig 833 BLAKE2B 2a7c70105d2d88edca9d771a21d39fba78ed25213fb922a48eae1e37d3eb2c07cce5ac24713cfdb336e1edd0def6f31aa79bac84ecc5a7d4ea80b4094cfccb26 SHA512 8a0564e14131c01aa93163a026fe9f87a2bebf4d9354b757233a1af81d7e276fb2e0dbc15e0d95ba89315a33d9751badd641755c901daa531d05547f4bcc9fb0
 DIST diffutils-3.10.tar.xz 1624240 BLAKE2B 24a90162b3d876e6378243f19a85a1f1bb4cdfe98d130dee684740a902f2987509d5830dd32df4e26678b468b96960f6f9785ffb922e828cb8b4acce0d8587f6 SHA512 219d2c815a120690c6589846271e43aee5c96c61a7ee4abbef97dfcdb3d6416652ed494b417de0ab6688c4322540d48be63b5e617beb6d20530b5d55d723ccbb
 DIST diffutils-3.10.tar.xz.sig 833 BLAKE2B 06650838d6a3327fda6b2ab09693170ec18b730b1f5981c8f3e2180b2c8a553307ae93199e4be0532a534a8a3f95e4a7b4fccbbd9e5f8d1b1cedd0816b0aac90 SHA512 91aa1fcfca224454e292540ea7813f4a0eb348f06a4374017326d524949775359fc833de597cc201c97f357eb6c675800828a6e3332572376f3554f1f2e1aca1

sdk_container/src/third_party/portage-stable/sys-apps/diffutils/diffutils-3.10_p20250103.ebuild

@@ -0,0 +1,58 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+VERIFY_SIG_OPENPGP_KEY_PATH=/usr/share/openpgp-keys/diffutils.asc
+inherit verify-sig
+
+DESCRIPTION="Tools to make diffs and compare files"
+HOMEPAGE="https://www.gnu.org/software/diffutils/"
+
+if [[ ${PV} == *_p* ]] ; then
+	# Subscribe to the 'platform-testers' ML to find these.
+	# Useful to test on our especially more niche arches and report issues upstream.
+	MY_COMMIT="242-d65b"
+	MY_P=${PN}-$(ver_cut 1-2).${MY_COMMIT}
+	SRC_URI="https://meyering.net/diff/${MY_P}.tar.xz"
+	SRC_URI+=" verify-sig? ( https://meyering.net/diff/${MY_P}.tar.xz.sig )"
+	S="${WORKDIR}"/${MY_P}
+else
+	SRC_URI="mirror://gnu/${PN}/${P}.tar.xz"
+	SRC_URI+=" verify-sig? ( mirror://gnu/${PN}/${P}.tar.xz.sig )"
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~arm64-macos ~ppc-macos ~x64-macos ~x64-solaris"
+fi
+
+LICENSE="GPL-2"
+SLOT="0"
+IUSE="nls"
+
+BDEPEND="
+	nls? ( sys-devel/gettext )
+	verify-sig? ( sec-keys/openpgp-keys-diffutils )
+"
+
+src_prepare() {
+	default
+
+	# Needed because of ${P}-diff-D-option-regression.patch
+	#touch man/diff.1 || die
+}
+
+src_configure() {
+	# Disable automagic dependency over libsigsegv; see bug #312351.
+	export ac_cv_libsigsegv=no
+
+	# required for >=glibc-2.26, bug #653914
+	use elibc_glibc && export gl_cv_func_getopt_gnu=yes
+
+	local myeconfargs=(
+		# Interferes with F_S (sets F_S=2)
+		--disable-gcc-warnings
+		--with-packager="Gentoo"
+		--with-packager-version="${PVR}"
+		--with-packager-bug-reports="https://bugs.gentoo.org/"
+		$(use_enable nls)
+	)
+	econf "${myeconfargs[@]}"
+}