app-misc/pax-utils: Sync with Gentoo

It's from Gentoo commit 7b86525c43f711bc047bc946789598bc88b1ec74.

sdk_container/src/third_party/portage-stable/app-misc/pax-utils/Manifest

@@ -1 +1,2 @@
 DIST pax-utils-1.3.7.tar.xz 113740 BLAKE2B d801df9c426f318c871655f238fe27b53e656c2789ef8508019997c98bbc540987b611642d87e76ae9f76a95f6cce1acd0b10e3491a146d1e3b3f727a6f96bdc SHA512 f1b87a564573da838a02c4cc10e0d5f9754c3b004ecb172a6290b48a8179b30695ae556942457dfac3caf07b91dd56eb1d801475c35e9708e4d671aa507f9576
+DIST pax-utils-1.3.8.tar.xz 123556 BLAKE2B 9e658334f37bfee90d4d168cdb81bc3b4012c38b569c22c3b01688408e90f4727043636ff8908e6c049fce7be5476ba86773f07cb192e3a34721c1469f69b48d SHA512 0dde95f86802729d80b7b38af84dec636e973f6abc70600633edcb05d3d5f95c1b2861300ce478dd7f798c7a1e5eccb1011c06c53adba38e11a996b69d463656

sdk_container/src/third_party/portage-stable/app-misc/pax-utils/pax-utils-1.3.8.ebuild

@@ -0,0 +1,77 @@
+# Copyright 2022-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+# Note: if bumping pax-utils because of syscall changes in glibc, please
+# revbump glibc and update the dependency in its ebuild for the affected
+# versions.
+PYTHON_COMPAT=( python3_{10..13} )
+
+inherit meson python-single-r1
+
+DESCRIPTION="ELF utils that can check files for security relevant properties"
+HOMEPAGE="https://wiki.gentoo.org/wiki/Hardened/PaX_Utilities"
+
+if [[ ${PV} == 9999 ]]; then
+	EGIT_REPO_URI="https://anongit.gentoo.org/git/proj/pax-utils.git"
+	inherit git-r3
+else
+	SRC_URI="
+		https://dev.gentoo.org/~sam/distfiles/${CATEGORY}/${PN}/${P}.tar.xz
+		https://dev.gentoo.org/~vapier/dist/${P}.tar.xz
+	"
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~arm64-macos ~ppc-macos ~x64-macos ~x64-solaris"
+fi
+
+LICENSE="GPL-2"
+SLOT="0"
+IUSE="caps man python seccomp test"
+REQUIRED_USE="
+	python? ( ${PYTHON_REQUIRED_USE} )
+	test? ( python )
+"
+RESTRICT="!test? ( test )"
+
+MY_PYTHON_DEPS="
+	${PYTHON_DEPS}
+	$(python_gen_cond_dep '
+		dev-python/pyelftools[${PYTHON_USEDEP}]
+	')
+"
+RDEPEND="
+	caps? ( >=sys-libs/libcap-2.24 )
+	python? ( ${MY_PYTHON_DEPS} )
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	caps? ( virtual/pkgconfig )
+	man? ( app-text/xmlto )
+	python? ( ${MY_PYTHON_DEPS} )
+"
+
+pkg_setup() {
+	if use test || use python; then
+		python-single-r1_pkg_setup
+	fi
+}
+
+src_configure() {
+	local emesonargs=(
+		"-Dlddtree_implementation=$(usex python python sh)"
+		$(meson_feature caps use_libcap)
+		$(meson_feature man build_manpages)
+		$(meson_use seccomp use_seccomp)
+		$(meson_use test tests)
+
+		# fuzzing is currently broken
+		-Duse_fuzzing=false
+	)
+	meson_src_configure
+}
+
+src_install() {
+	meson_src_install
+
+	use python && python_fix_shebang "${ED}"/usr/bin/lddtree
+}

sdk_container/src/third_party/portage-stable/app-misc/pax-utils/pax-utils-9999.ebuild

@@ -6,7 +6,7 @@ EAPI=8
 # Note: if bumping pax-utils because of syscall changes in glibc, please
 # revbump glibc and update the dependency in its ebuild for the affected
 # versions.
-PYTHON_COMPAT=( python3_{10..12} )
+PYTHON_COMPAT=( python3_{10..13} )
 
 inherit meson python-single-r1