diff --git a/sdk_container/src/third_party/portage-stable/sys-devel/gnuconfig/gnuconfig-20110202.ebuild b/sdk_container/src/third_party/portage-stable/sys-devel/gnuconfig/gnuconfig-20110202.ebuild
new file mode 100644
index 0000000000..13b525abbb
--- /dev/null
+++ b/sdk_container/src/third_party/portage-stable/sys-devel/gnuconfig/gnuconfig-20110202.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/sys-devel/gnuconfig/gnuconfig-20110202.ebuild,v 1.3 2011/08/15 03:25:55 vapier Exp $
+
+EAPI="2"
+
+inherit eutils
+if [[ ${PV} == "99999999" ]] ; then
+	EGIT_REPO_URI="git://git.savannah.gnu.org/config.git"
+	inherit git
+else
+	SRC_URI="mirror://gentoo/${P}.tar.bz2"
+	KEYWORDS="alpha amd64 arm hppa ia64 m68k ~mips ppc ppc64 s390 sh sparc x86 ~ppc-aix ~sparc-fbsd ~x86-fbsd ~x64-freebsd ~x86-freebsd ~hppa-hpux ~x86-interix ~amd64-linux ~ia64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~m68k-mint ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+fi
+
+DESCRIPTION="Updated config.sub and config.guess file from GNU"
+HOMEPAGE="http://savannah.gnu.org/projects/config"
+
+LICENSE="GPL-2"
+SLOT="0"
+IUSE=""
+
+S=${WORKDIR}
+
+maint_pkg_create() {
+	cd "${S}"
+
+	local ver=$(head -n 1 ChangeLog | awk '{print $1}' | sed -e 's:-::g')
+	[[ ${#ver} != 8 ]] && die "invalid version '${ver}'"
+
+	cp "${FILESDIR}"/${PV}/*.patch . || die
+
+	local tar="${T}/gnuconfig-${ver}.tar.bz2"
+	tar -jcf ${tar} . || die "creating tar failed"
+	einfo "Packaged tar now available:"
+	einfo "$(du -b ${tar})"
+}
+
+src_unpack() {
+	if [[ ${PV} == "99999999" ]] ; then
+		git_src_unpack
+		maint_pkg_create
+	else
+		unpack ${A}
+	fi
+}
+
+src_prepare() {
+	epatch "${WORKDIR}"/*.patch
+	use elibc_uclibc && sed -i 's:linux-gnu:linux-uclibc:' testsuite/config-guess.data #180637
+}
+
+src_compile() { :;}
+
+src_install() {
+	insinto /usr/share/${PN}
+	doins config.{sub,guess} || die
+	fperms +x /usr/share/${PN}/config.{sub,guess}
+	dodoc ChangeLog
+}