dev-libs/elfutils: Sync with Gentoo

It's from Gentoo commit 0998c45f60570c31e5833e333f226056f974202c.

sdk_container/src/third_party/portage-stable/dev-libs/elfutils/elfutils-0.191-r1.ebuild

@@ -4,32 +4,46 @@
 EAPI=8
 
 VERIFY_SIG_OPENPGP_KEY_PATH=/usr/share/openpgp-keys/elfutils.gpg
-inherit autotools flag-o-matic multilib-minimal verify-sig
+inherit autotools flag-o-matic multilib-minimal
 
 DESCRIPTION="Libraries/utilities to handle ELF objects (drop in replacement for libelf)"
 HOMEPAGE="https://sourceware.org/elfutils/"
-SRC_URI="https://sourceware.org/elfutils/ftp/${PV}/${P}.tar.bz2"
+if [[ ${PV} == 9999 ]] ; then
-SRC_URI+=" verify-sig? ( https://sourceware.org/elfutils/ftp/${PV}/${P}.tar.bz2.sig )"
+	EGIT_REPO_URI="https://sourceware.org/git/elfutils.git"
+	inherit git-r3
+
+	BDEPEND="
+		sys-devel/bison
+		sys-devel/flex
+	"
+else
+	inherit verify-sig
+	SRC_URI="https://sourceware.org/elfutils/ftp/${PV}/${P}.tar.bz2"
+	SRC_URI+=" verify-sig? ( https://sourceware.org/elfutils/ftp/${PV}/${P}.tar.bz2.sig )"
+
+	KEYWORDS="~alpha amd64 arm arm64 ~hppa ~ia64 ~loong ~m68k ~mips ppc ppc64 ~riscv ~s390 ~sparc x86 ~amd64-linux ~x86-linux"
+
+	BDEPEND="verify-sig? ( >=sec-keys/openpgp-keys-elfutils-20240301 )"
+fi
 
 LICENSE="|| ( GPL-2+ LGPL-3+ ) utils? ( GPL-3+ )"
 SLOT="0"
-KEYWORDS="~alpha amd64 arm arm64 ~hppa ~ia64 ~loong ~m68k ~mips ppc ppc64 ~riscv ~s390 ~sparc x86 ~amd64-linux ~x86-linux"
+IUSE="bzip2 debuginfod lzma nls test +utils valgrind zstd"
-IUSE="bzip2 debuginfod lzma nls static-libs test +utils zstd"
 RESTRICT="!test? ( test )"
 
 RDEPEND="
 	!dev-libs/libelf
-	>=sys-libs/zlib-1.2.8-r1[static-libs?,${MULTILIB_USEDEP}]
+	>=sys-libs/zlib-1.2.8-r1[${MULTILIB_USEDEP}]
-	bzip2? ( >=app-arch/bzip2-1.0.6-r4[static-libs?,${MULTILIB_USEDEP}] )
+	bzip2? ( >=app-arch/bzip2-1.0.6-r4[${MULTILIB_USEDEP}] )
 	debuginfod? (
 		app-arch/libarchive:=
 		dev-db/sqlite:3=
 		net-libs/libmicrohttpd:=
 
-		net-misc/curl[static-libs?,${MULTILIB_USEDEP}]
+		net-misc/curl[${MULTILIB_USEDEP}]
 	)
-	lzma? ( >=app-arch/xz-utils-5.0.5-r1[static-libs?,${MULTILIB_USEDEP}] )
+	lzma? ( >=app-arch/xz-utils-5.0.5-r1[${MULTILIB_USEDEP}] )
-	zstd? ( app-arch/zstd:=[static-libs?,${MULTILIB_USEDEP}] )
+	zstd? ( app-arch/zstd:=[${MULTILIB_USEDEP}] )
 	elibc_musl? (
 		dev-libs/libbsd
 		sys-libs/argp-standalone
@@ -39,13 +53,12 @@ RDEPEND="
 "
 DEPEND="
 	${RDEPEND}
+	valgrind? ( dev-debug/valgrind )
 "
-BDEPEND="
+BDEPEND+="
-	app-alternatives/lex
 	sys-devel/m4
 	virtual/pkgconfig
 	nls? ( sys-devel/gettext )
-	verify-sig? ( >=sec-keys/openpgp-keys-elfutils-20240301 )
 "
 
 PATCHES=(
@@ -57,10 +70,6 @@ PATCHES=(
 src_prepare() {
 	default
 
-	if ! use static-libs; then
-		sed -i -e '/^lib_LIBRARIES/s:=.*:=:' -e '/^%.os/s:%.o$::' lib{asm,dw,elf}/Makefile.in || die
-	fi
-
 	eautoreconf
 
 	# https://sourceware.org/PR23914
@@ -78,10 +87,13 @@ src_configure() {
 }
 
 multilib_src_configure() {
+	unset LEX YACC
+
 	local myeconfargs=(
 		$(use_enable nls)
 		$(multilib_native_use_enable debuginfod)
 		$(use_enable debuginfod libdebuginfod)
+		$(use_enable valgrind valgrind-annotations)
 
 		# explicitly disable thread safety, it's not recommended by upstream
 		# doesn't build either on musl.
@@ -97,6 +109,8 @@ multilib_src_configure() {
 		$(use_with zstd)
 	)
 
+	[[ ${PV} == 9999 ]] && myeconfargs+=( --enable-maintainer-mode )
+
 	# Needed because sets alignment macro
 	is-flagq -fsanitize=address && myeconfargs+=( --enable-sanitize-address )
 	is-flagq -fsanitize=undefined && myeconfargs+=( --enable-sanitize-undefined )
@@ -115,8 +129,8 @@ multilib_src_install_all() {
 
 	dodoc NOTES
 
-	# These build quick, and are needed for most tests, so don't
+	# These build quick, and are needed for most tests, so we don't
-	# disable their building when the USE flag is disabled.
+	# disable building them when the USE flag is disabled.
 	if ! use utils; then
 		rm -rf "${ED}"/usr/bin || die
 	fi

sdk_container/src/third_party/portage-stable/dev-libs/elfutils/elfutils-0.191-r2.ebuild

@@ -0,0 +1,141 @@
+# Copyright 2003-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+VERIFY_SIG_OPENPGP_KEY_PATH=/usr/share/openpgp-keys/elfutils.gpg
+inherit autotools flag-o-matic multilib-minimal
+
+DESCRIPTION="Libraries/utilities to handle ELF objects (drop in replacement for libelf)"
+HOMEPAGE="https://sourceware.org/elfutils/"
+if [[ ${PV} == 9999 ]] ; then
+	EGIT_REPO_URI="https://sourceware.org/git/elfutils.git"
+	inherit git-r3
+
+	BDEPEND="
+		sys-devel/bison
+		sys-devel/flex
+	"
+else
+	inherit verify-sig
+	SRC_URI="https://sourceware.org/elfutils/ftp/${PV}/${P}.tar.bz2"
+	SRC_URI+=" verify-sig? ( https://sourceware.org/elfutils/ftp/${PV}/${P}.tar.bz2.sig )"
+
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux"
+
+	BDEPEND="verify-sig? ( >=sec-keys/openpgp-keys-elfutils-20240301 )"
+fi
+
+LICENSE="|| ( GPL-2+ LGPL-3+ ) utils? ( GPL-3+ )"
+SLOT="0"
+IUSE="bzip2 debuginfod lzma nls static-libs test +utils valgrind zstd"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	!dev-libs/libelf
+	>=sys-libs/zlib-1.2.8-r1[static-libs?,${MULTILIB_USEDEP}]
+	bzip2? ( >=app-arch/bzip2-1.0.6-r4[static-libs?,${MULTILIB_USEDEP}] )
+	debuginfod? (
+		app-arch/libarchive:=
+		dev-db/sqlite:3=
+		net-libs/libmicrohttpd:=
+
+		net-misc/curl[static-libs?,${MULTILIB_USEDEP}]
+	)
+	lzma? ( >=app-arch/xz-utils-5.0.5-r1[static-libs?,${MULTILIB_USEDEP}] )
+	zstd? ( app-arch/zstd:=[static-libs?,${MULTILIB_USEDEP}] )
+	elibc_musl? (
+		dev-libs/libbsd
+		sys-libs/argp-standalone
+		sys-libs/fts-standalone
+		sys-libs/obstack-standalone
+	)
+"
+DEPEND="
+	${RDEPEND}
+	valgrind? ( dev-debug/valgrind )
+"
+BDEPEND+="
+	sys-devel/m4
+	virtual/pkgconfig
+	nls? ( sys-devel/gettext )
+"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-0.189-musl-aarch64-regs.patch
+	"${FILESDIR}"/${PN}-0.191-musl-macros.patch
+	"${FILESDIR}"/${PN}-0.191-avoid-overriding-libcxx-system-header.patch
+)
+
+src_prepare() {
+	default
+
+	eautoreconf
+
+	if ! use static-libs; then
+		sed -i -e '/^lib_LIBRARIES/s:=.*:=:' -e '/^%.os/s:%.o$::' lib{asm,dw,elf}/Makefile.in || die
+	fi
+
+	# https://sourceware.org/PR23914
+	sed -i 's:-Werror::' */Makefile.in || die
+}
+
+src_configure() {
+	# bug #407135
+	use test && append-flags -g
+
+	# bug 660738
+	filter-flags -fno-asynchronous-unwind-tables
+
+	multilib-minimal_src_configure
+}
+
+multilib_src_configure() {
+	unset LEX YACC
+
+	local myeconfargs=(
+		$(use_enable nls)
+		$(multilib_native_use_enable debuginfod)
+		$(use_enable debuginfod libdebuginfod)
+		$(use_enable valgrind valgrind-annotations)
+
+		# explicitly disable thread safety, it's not recommended by upstream
+		# doesn't build either on musl.
+		--disable-thread-safety
+
+		# Valgrind option is just for running tests under it; dodgy under sandbox
+		# and indeed even w/ glibc with newer instructions.
+		--disable-valgrind
+		--program-prefix="eu-"
+		--with-zlib
+		$(use_with bzip2 bzlib)
+		$(use_with lzma)
+		$(use_with zstd)
+	)
+
+	[[ ${PV} == 9999 ]] && myeconfargs+=( --enable-maintainer-mode )
+
+	# Needed because sets alignment macro
+	is-flagq -fsanitize=address && myeconfargs+=( --enable-sanitize-address )
+	is-flagq -fsanitize=undefined && myeconfargs+=( --enable-sanitize-undefined )
+
+	ECONF_SOURCE="${S}" econf "${myeconfargs[@]}"
+}
+
+multilib_src_test() {
+	env LD_LIBRARY_PATH="${BUILD_DIR}/libelf:${BUILD_DIR}/libebl:${BUILD_DIR}/libdw:${BUILD_DIR}/libasm" \
+		LC_ALL="C" \
+		emake check VERBOSE=1
+}
+
+multilib_src_install_all() {
+	einstalldocs
+
+	dodoc NOTES
+
+	# These build quick, and are needed for most tests, so we don't
+	# disable building them when the USE flag is disabled.
+	if ! use utils; then
+		rm -rf "${ED}"/usr/bin || die
+	fi
+}

sdk_container/src/third_party/portage-stable/dev-libs/elfutils/elfutils-9999.ebuild

@@ -0,0 +1,140 @@
+# Copyright 2003-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+VERIFY_SIG_OPENPGP_KEY_PATH=/usr/share/openpgp-keys/elfutils.gpg
+inherit autotools flag-o-matic multilib-minimal
+
+DESCRIPTION="Libraries/utilities to handle ELF objects (drop in replacement for libelf)"
+HOMEPAGE="https://sourceware.org/elfutils/"
+if [[ ${PV} == 9999 ]] ; then
+	EGIT_REPO_URI="https://sourceware.org/git/elfutils.git"
+	inherit git-r3
+
+	BDEPEND="
+		sys-devel/bison
+		sys-devel/flex
+	"
+else
+	inherit verify-sig
+	SRC_URI="https://sourceware.org/elfutils/ftp/${PV}/${P}.tar.bz2"
+	SRC_URI+=" verify-sig? ( https://sourceware.org/elfutils/ftp/${PV}/${P}.tar.bz2.sig )"
+
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux"
+
+	BDEPEND="verify-sig? ( >=sec-keys/openpgp-keys-elfutils-20240301 )"
+fi
+
+LICENSE="|| ( GPL-2+ LGPL-3+ ) utils? ( GPL-3+ )"
+SLOT="0"
+IUSE="bzip2 debuginfod lzma nls static-libs test +utils valgrind zstd"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	!dev-libs/libelf
+	>=sys-libs/zlib-1.2.8-r1[static-libs?,${MULTILIB_USEDEP}]
+	bzip2? ( >=app-arch/bzip2-1.0.6-r4[static-libs?,${MULTILIB_USEDEP}] )
+	debuginfod? (
+		app-arch/libarchive:=
+		dev-db/sqlite:3=
+		net-libs/libmicrohttpd:=
+
+		net-misc/curl[static-libs?,${MULTILIB_USEDEP}]
+	)
+	lzma? ( >=app-arch/xz-utils-5.0.5-r1[static-libs?,${MULTILIB_USEDEP}] )
+	zstd? ( app-arch/zstd:=[static-libs?,${MULTILIB_USEDEP}] )
+	elibc_musl? (
+		dev-libs/libbsd
+		sys-libs/argp-standalone
+		sys-libs/fts-standalone
+		sys-libs/obstack-standalone
+	)
+"
+DEPEND="
+	${RDEPEND}
+	valgrind? ( dev-debug/valgrind )
+"
+BDEPEND+="
+	sys-devel/m4
+	virtual/pkgconfig
+	nls? ( sys-devel/gettext )
+"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-0.189-musl-aarch64-regs.patch
+	"${FILESDIR}"/${PN}-0.191-musl-macros.patch
+)
+
+src_prepare() {
+	default
+
+	eautoreconf
+
+	if ! use static-libs; then
+		sed -i -e '/^lib_LIBRARIES/s:=.*:=:' -e '/^%.os/s:%.o$::' lib{asm,dw,elf}/Makefile.in || die
+	fi
+
+	# https://sourceware.org/PR23914
+	sed -i 's:-Werror::' */Makefile.in || die
+}
+
+src_configure() {
+	# bug #407135
+	use test && append-flags -g
+
+	# bug 660738
+	filter-flags -fno-asynchronous-unwind-tables
+
+	multilib-minimal_src_configure
+}
+
+multilib_src_configure() {
+	unset LEX YACC
+
+	local myeconfargs=(
+		$(use_enable nls)
+		$(multilib_native_use_enable debuginfod)
+		$(use_enable debuginfod libdebuginfod)
+		$(use_enable valgrind valgrind-annotations)
+
+		# explicitly disable thread safety, it's not recommended by upstream
+		# doesn't build either on musl.
+		--disable-thread-safety
+
+		# Valgrind option is just for running tests under it; dodgy under sandbox
+		# and indeed even w/ glibc with newer instructions.
+		--disable-valgrind
+		--program-prefix="eu-"
+		--with-zlib
+		$(use_with bzip2 bzlib)
+		$(use_with lzma)
+		$(use_with zstd)
+	)
+
+	[[ ${PV} == 9999 ]] && myeconfargs+=( --enable-maintainer-mode )
+
+	# Needed because sets alignment macro
+	is-flagq -fsanitize=address && myeconfargs+=( --enable-sanitize-address )
+	is-flagq -fsanitize=undefined && myeconfargs+=( --enable-sanitize-undefined )
+
+	ECONF_SOURCE="${S}" econf "${myeconfargs[@]}"
+}
+
+multilib_src_test() {
+	env LD_LIBRARY_PATH="${BUILD_DIR}/libelf:${BUILD_DIR}/libebl:${BUILD_DIR}/libdw:${BUILD_DIR}/libasm" \
+		LC_ALL="C" \
+		emake check VERBOSE=1
+}
+
+multilib_src_install_all() {
+	einstalldocs
+
+	dodoc NOTES
+
+	# These build quick, and are needed for most tests, so we don't
+	# disable building them when the USE flag is disabled.
+	if ! use utils; then
+		rm -rf "${ED}"/usr/bin || die
+	fi
+}