dev-python/jaraco-text: Sync with Gentoo

It's from Gentoo commit ebff9881ed725e1e04fb8dfdbe7ce8f50f52f495.

sdk_container/src/third_party/portage-stable/dev-python/jaraco-text/Manifest

@@ -1 +1,2 @@
 DIST jaraco.text-3.12.0.tar.gz 16329 BLAKE2B e1314b3121d5d75ac4a986a342c3290f5523bb45be8bf8e994ed87188712464e75a805498a7d846aea157aa8592fbca444842d1b70a21e0add49e89dfa743a7a SHA512 75068006c96dae3b8d21228f2ae21820939c68b1fb7e5db35bd0c1126a20399eb4d99c6bea15e88076599956c4b41104558cd32d860d8f4fd4e96aeeb22711c9
+DIST jaraco_text-3.12.1.tar.gz 16580 BLAKE2B 89f11877052e6b7cacbee4ae53ea140ce337a3a8f25657c558e3634378d20ac70206fd188f8492bdc725ebfec94c7f553ec61a9a3be97738918746fab79a9414 SHA512 4a459e497259de8dc37fbe92eec19973f5d1425f23212221885339a9c7b0f432301978c3c918f4cdd4e1cb3e50b465aad07634ab8cf40f86151d08b150d097e4

sdk_container/src/third_party/portage-stable/dev-python/jaraco-text/jaraco-text-3.12.0.ebuild

@@ -1,4 +1,4 @@
-# Copyright 1999-2023 Gentoo Authors
+# Copyright 1999-2024 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 # please keep this ebuild at EAPI 8 -- sys-apps/portage dep
@@ -7,7 +7,7 @@ EAPI=8
 DISTUTILS_USE_PEP517=flit
 PYPI_NO_NORMALIZE=1
 PYPI_PN=${PN/-/.}
-PYTHON_COMPAT=( python3_{10..12} pypy3 )
+PYTHON_COMPAT=( python3_{10..13} pypy3 )
 
 inherit distutils-r1 pypi
 

sdk_container/src/third_party/portage-stable/dev-python/jaraco-text/jaraco-text-3.12.1.ebuild

@@ -0,0 +1,56 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+# please keep this ebuild at EAPI 8 -- sys-apps/portage dep
+EAPI=8
+
+DISTUTILS_USE_PEP517=flit
+PYPI_PN=${PN/-/.}
+PYTHON_COMPAT=( python3_{10..13} pypy3 )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Text utilities used by other projects by developer jaraco"
+HOMEPAGE="
+	https://github.com/jaraco/jaraco.text/
+	https://pypi.org/project/jaraco.text/
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~arm64-macos ~ppc-macos ~x64-macos ~x64-solaris"
+
+RDEPEND="
+	>=dev-python/jaraco-context-4.1.1-r1[${PYTHON_USEDEP}]
+	>=dev-python/jaraco-functools-3.5.0-r1[${PYTHON_USEDEP}]
+"
+
+distutils_enable_tests pytest
+
+src_configure() {
+	grep -q 'build-backend = "setuptools' pyproject.toml ||
+		die "Upstream changed build-backend, recheck"
+	# write a custom pyproject.toml to ease setuptools bootstrap
+	cat > pyproject.toml <<-EOF || die
+		[build-system]
+		requires = ["flit_core >=3.2,<4"]
+		build-backend = "flit_core.buildapi"
+
+		[project]
+		name = "jaraco.text"
+		version = "${PV}"
+		description = "Module for text manipulation"
+	EOF
+
+	# remove CLI tools, they have annoying deps, no entry points
+	# and since there are dashes in their names, they can't be imported
+	# anyway
+	rm jaraco/text/*-*.py || die
+}
+
+python_install() {
+	distutils-r1_python_install
+	# rename to workaround a bug in pkg_resources
+	# https://bugs.gentoo.org/834522
+	mv "${D}$(python_get_sitedir)"/jaraco{_,.}text-${PV}.dist-info || die
+}