app-containers/incus: Sync with Gentoo

It's from Gentoo commit be31025842e3924d94ce4886ce9486eb0e31c5f6.

sdk_container/src/third_party/portage-stable/app-containers/incus/Manifest

@@ -2,5 +2,5 @@ DIST incus-6.0.3.tar.xz 11916020 BLAKE2B d3d998bd50124604c52ff007eefed586c216ce1
 DIST incus-6.0.3.tar.xz.asc 833 BLAKE2B 38835ab036709161150992cb40df4ff1ae1887d4f3e0b037d0415f75d2bb711cb3c5945bffe1b91d289acfb7e19e726964278e5c2ab31731ba9f7534f139dec7 SHA512 7d5360ab91aafe1d047a60e38a07e24c3c7b158e753087a943ec5e59d6a27c19a872080c9007b6cf592040d3408845bc188d76f6e732408d0680a3782cebce47
 DIST incus-6.0.4.tar.xz 12000208 BLAKE2B 99a4ba40d2eea48515b88f4534c282adc925fe1b5487dc98901f000894b3781aec89f617d2246314cf9a95a7d65531e486c4092f8939722e1b3c2bf7d33063c8 SHA512 14a5cdad3f9365d58e526c8f451d9e7a57729010073caff31256e0b94d28206adc82ead4820278e7eac17b74d22a76d9f3b9f5f8424ddbfa6b74a5cea13e019f
 DIST incus-6.0.4.tar.xz.asc 833 BLAKE2B 96c94cde55cd2e9f7f28db7adb098adf4895437d300dfd42aeac540cdab6677fb604831c28f40f8581e60b89b228557d81696cd64950a1c2147b445a5ec58b30 SHA512 1ef2063eab424467c805f8c86b5b0caca848f46d2ef7ebf602049fe32ee15a7e1006d5a2710b355604aef73802b4333cd0428c772e1c5fc4da588c2cd7ee1694
-DIST incus-6.13.tar.xz 12416404 BLAKE2B 0eca3b80762e9473be21f29157eb42d655a09db97084f6cccd1317595f96593c866110c19a4a42592ae556e8f2f3e40153a7430730373cdb777261bc4a8f0d5e SHA512 80411e23aa95f021f349463b15146444bba7f5cad42e094ff099ec70df8083d7b54d8374ef659d3f4d01afbcbf4287b7238e973d53fecd9a7af046df85b1b05f
+DIST incus-6.14.tar.xz 12509468 BLAKE2B ec3bb614088d82e07c13169a6b26d8c83214fddbdf30049d58f2cca2678a16ccb6acca7bba68d4e15a514dad71639a144a7b2f4b9f3efdf9c8ca8d750692e250 SHA512 186abb32dcfbe851f04131ea7a9256fafaa465d40379e825554275697e04f005920c09939a8cb199b499b60df667921900c4a2d5b9a7ab9bd20b3e473468dbf1
-DIST incus-6.13.tar.xz.asc 833 BLAKE2B fbdb41110452716aa333f444801152456ec1196cbdb151c5dfdb940d3e82e39cbbc70990ec999b723938ec3986deafff0c1e77376cdd19fb862aa8c59083d363 SHA512 a29978fd9d9f89f7ae6585f150cf78ec7819360e189ce6bbb5559049cecd2b667a46857a852a77d22edba60fce083c2bfccbf89535dad7d415e82c0eec995700
+DIST incus-6.14.tar.xz.asc 833 BLAKE2B c9cfa631bb316234a6958f2aa3e708e32ea2fca34357700e7d1e38723be539f5b6b1484597c18baca1f22d922c7aca148463dfc0b818f7809126e6873e4826b5 SHA512 6a2f4ceeab44462cca74799a1c135eeb17cbece3d270c5195c3eacda8ea24419fc34cab6d157dbfed803bb269df42a02abc417b98887cec5f10b0ec70b430644

sdk_container/src/third_party/portage-stable/app-containers/incus/files/incus-6.14-fix-qemu-memory-calculation-logic.patch

@@ -0,0 +1,35 @@
+From 60c8f084a7cb9e38b5003fc056538f6631609cb8 Mon Sep 17 00:00:00 2001
+From: =?UTF-8?q?St=C3=A9phane=20Graber?= <stgraber@stgraber.org>
+Date: Tue, 1 Jul 2025 21:24:04 -0400
+Subject: [PATCH] incusd/instance/qemu: Fix memory calculation logic
+MIME-Version: 1.0
+Content-Type: text/plain; charset=UTF-8
+Content-Transfer-Encoding: 8bit
+
+This fixes another issue with the logic where a system with no detected
+physical bits would cause a 0 value which would then be decreased,
+leading to the maximum value possible of 1TB.
+
+Signed-off-by: Stéphane Graber <stgraber@stgraber.org>
+---
+ internal/server/instance/drivers/driver_qemu.go | 7 ++-----
+ 1 file changed, 2 insertions(+), 5 deletions(-)
+
+diff --git a/internal/server/instance/drivers/driver_qemu.go b/internal/server/instance/drivers/driver_qemu.go
+index 995d1d31ed5..2897226d930 100644
+--- a/internal/server/instance/drivers/driver_qemu.go
++++ b/internal/server/instance/drivers/driver_qemu.go
+@@ -4183,11 +4183,8 @@ func (d *qemu) addCPUMemoryConfig(conf *[]cfg.Section, cpuType string, cpuInfo *
+ 			}
+ 		}
+ 
+-		if cpuType == "host" && lowestPhysBits > 0 {
+-			// Line up cpuPhysBits with the lowest physical CPU value.
+-			cpuPhysBits = lowestPhysBits
+-		} else if lowestPhysBits < cpuPhysBits {
+-			// Reduce curPhysBits below the default of 39 if a physical CPU uses a lower value.
++		// If a physical address size was detected, either align it with the VM (CPU passthrough) or use it as an upper bound.
++		if lowestPhysBits > 0 && (cpuType == "host" || lowestPhysBits < cpuPhysBits) {
+ 			cpuPhysBits = lowestPhysBits
+ 		}
+ 

sdk_container/src/third_party/portage-stable/app-containers/incus/incus-6.13.ebuild

@@ -1,228 +0,0 @@
-# Copyright 1999-2025 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-inherit go-env go-module linux-info optfeature systemd toolchain-funcs verify-sig
-
-DESCRIPTION="Modern, secure and powerful system container and virtual machine manager"
-HOMEPAGE="https://linuxcontainers.org/incus/introduction/ https://github.com/lxc/incus"
-SRC_URI="https://linuxcontainers.org/downloads/incus/${P}.tar.xz
-	verify-sig? ( https://linuxcontainers.org/downloads/incus/${P}.tar.xz.asc )"
-
-LICENSE="Apache-2.0 BSD LGPL-3 MIT"
-SLOT="0/stable"
-KEYWORDS="~amd64 ~arm64"
-IUSE="apparmor fuidshift nls qemu"
-
-DEPEND="acct-group/incus
-	acct-group/incus-admin
-	app-arch/xz-utils
-	>=app-containers/lxc-5.0.0:=[apparmor?,seccomp(+)]
-	dev-db/sqlite:3
-	>=dev-libs/cowsql-1.15.7
-	dev-libs/lzo
-	>=dev-libs/raft-0.22.1:=[lz4]
-	>=dev-util/xdelta-3.0[lzma(+)]
-	net-dns/dnsmasq[dhcp]
-	sys-libs/libcap
-	virtual/udev"
-RDEPEND="${DEPEND}
-	|| (
-		net-firewall/iptables
-		net-firewall/nftables[json]
-	)
-	fuidshift? ( !app-containers/lxd )
-	net-firewall/ebtables
-	sys-apps/iproute2
-	sys-fs/fuse:*
-	>=sys-fs/lxcfs-5.0.0
-	sys-fs/squashfs-tools[lzma]
-	virtual/acl
-	apparmor? ( sec-policy/apparmor-profiles )
-	qemu? (
-		app-cdr/cdrtools
-		app-emulation/qemu[spice,usbredir,virtfs]
-		sys-apps/gptfdisk
-	)"
-BDEPEND=">=dev-lang/go-1.21
-	nls? ( sys-devel/gettext )
-	verify-sig? ( sec-keys/openpgp-keys-linuxcontainers )"
-
-CONFIG_CHECK="
-	~AIO
-	~CGROUPS
-	~IPC_NS
-	~NET_NS
-	~PID_NS
-
-	~SECCOMP
-	~USER_NS
-	~UTS_NS
-
-	~KVM
-	~MACVTAP
-	~VHOST_VSOCK
-"
-
-ERROR_AIO="CONFIG_AIO is required."
-ERROR_IPC_NS="CONFIG_IPC_NS is required."
-ERROR_NET_NS="CONFIG_NET_NS is required."
-ERROR_PID_NS="CONFIG_PID_NS is required."
-ERROR_SECCOMP="CONFIG_SECCOMP is required."
-ERROR_UTS_NS="CONFIG_UTS_NS is required."
-
-WARNING_KVM="CONFIG_KVM and CONFIG_KVM_AMD/-INTEL is required for virtual machines."
-WARNING_MACVTAP="CONFIG_MACVTAP is required for virtual machines."
-WARNING_VHOST_VSOCK="CONFIG_VHOST_VSOCK is required for virtual machines."
-
-# Go magic.
-QA_PREBUILT="/usr/bin/incus
-	/usr/bin/incus-agent
-	/usr/bin/incus-benchmark
-	/usr/bin/incus-migrate
-	/usr/bin/lxc-to-incus
-	/usr/sbin/fuidshift
-	/usr/sbin/incusd
-	/usr/sbin/lxd-to-incus"
-
-VERIFY_SIG_OPENPGP_KEY_PATH=/usr/share/openpgp-keys/linuxcontainers.asc
-
-# The testsuite must be run as root.
-# make: *** [Makefile:156: check] Error 1
-RESTRICT="test"
-
-GOPATH="${S}/_dist"
-
-src_unpack() {
-	verify-sig_src_unpack
-	go-module_src_unpack
-}
-
-src_prepare() {
-	export GOPATH="${S}/_dist"
-
-	default
-
-	sed -i \
-		-e "s:\./configure:./configure --prefix=/usr --libdir=${EPREFIX}/usr/lib/incus:g" \
-		-e "s:make:make ${MAKEOPTS}:g" \
-		Makefile || die
-
-	sed -i \
-		-e "s:/usr/share/OVMF:/usr/share/edk2/OvmfX64:g" \
-		-e "s:OVMF_VARS.ms.fd:OVMF_VARS.fd:g" \
-		internal/server/instance/drivers/edk2/driver_edk2.go || die "Failed to fix hardcoded ovmf paths."
-
-	cp "${FILESDIR}"/incus-0.4.service "${T}"/incus.service || die
-	if use apparmor; then
-		sed -i \
-			'/^EnvironmentFile=.*/a ExecStartPre=\/usr\/libexec\/lxc\/lxc-apparmor-load' \
-			"${T}"/incus.service || die
-	fi
-
-	# Disable -Werror's from go modules.
-	find "${S}" -name "cgo.go" -exec sed -i "s/ -Werror / /g" {} + || die
-}
-
-src_configure() { :; }
-
-src_compile() {
-	export GOPATH="${S}/_dist"
-	export CGO_LDFLAGS_ALLOW="-Wl,-z,now"
-
-	for k in incus-benchmark incus-simplestreams incus-user incus lxc-to-incus lxd-to-incus ; do
-		ego install -v -x "${S}/cmd/${k}"
-	done
-
-	if use fuidshift ; then
-		ego install -v -x "${S}/cmd/fuidshift"
-	fi
-
-	ego install -v -x -tags libsqlite3 "${S}"/cmd/incusd
-
-	# Needs to be built statically
-	CGO_ENABLED=0 go install -v -tags netgo "${S}"/cmd/incus-migrate
-	CGO_ENABLED=0 go install -v -tags agent,netgo "${S}"/cmd/incus-agent
-
-	use nls && emake build-mo
-}
-
-src_test() {
-	emake check
-}
-
-src_install() {
-	export GOPATH="${S}/_dist"
-
-	export GOHOSTARCH=$(go-env_goarch "${CBUILD}")
-	if [[ "${GOARCH}" != "${GOHOSTARCH}" ]]; then
-		local bindir="_dist/bin/linux_${GOARCH}"
-	else
-		local bindir="_dist/bin"
-	fi
-
-	newsbin "${FILESDIR}"/incus-startup-0.4.sh incus-startup
-
-	# Admin tools
-	for l in incusd incus-user lxd-to-incus ; do
-		dosbin ${bindir}/${l}
-	done
-
-	# User tools
-	for m in incus-agent incus-benchmark incus-migrate incus-simplestreams incus lxc-to-incus ; do
-		dobin ${bindir}/${m}
-	done
-
-	# fuidshift, should be moved under admin tools at some point
-	if use fuidshift ; then
-		dosbin ${bindir}/fuidshift
-	fi
-
-	newconfd "${FILESDIR}"/incus-6.0.confd incus
-	newinitd "${FILESDIR}"/incus-6.0.initd incus
-	newinitd "${FILESDIR}"/incus-user-0.4.initd incus-user
-
-	systemd_dounit "${T}"/incus.service
-	systemd_newunit "${FILESDIR}"/incus-0.4.socket incus.socket
-	systemd_newunit "${FILESDIR}"/incus-startup-0.4.service incus-startup.service
-	systemd_newunit "${FILESDIR}"/incus-user-0.4.service incus-user.service
-	systemd_newunit "${FILESDIR}"/incus-user-0.4.socket incus-user.socket
-
-	if ! tc-is-cross-compiler; then
-		# Generate and install shell completion files.
-		mkdir -p "${D}"/usr/share/{bash-completion/completions/,fish/vendor_completions.d/,zsh/site-functions/} || die
-		"${bindir}"/incus completion bash > "${D}"/usr/share/bash-completion/completions/incus || die
-		"${bindir}"/incus completion fish > "${D}"/usr/share/fish/vendor_completions.d/incus.fish || die
-		"${bindir}"/incus completion zsh > "${D}"/usr/share/zsh/site-functions/_incus || die
-	else
-		ewarn "Shell completion files not installed! Install them manually with incus completion --help"
-	fi
-
-	dodoc AUTHORS
-	dodoc -r doc/*
-	use nls && domo po/*.mo
-
-	# Incus needs INCUS_EDK2_PATH in env to find OVMF files for virtual machines, #946184
-	newenvd - 90incus <<- _EOF_
-		INCUS_EDK2_PATH=${EPREFIX}/usr/share/edk2-ovmf
-	_EOF_
-}
-
-pkg_postinst() {
-	elog
-	elog "Please see"
-	elog "  https://wiki.gentoo.org/wiki/Incus"
-	elog "  https://wiki.gentoo.org/wiki/Incus#Migrating_from_LXD"
-	elog
-	optfeature "OCI container images support" app-containers/skopeo app-containers/umoci
-	optfeature "support for ACME certificate issuance" app-crypt/lego
-	optfeature "btrfs storage backend" sys-fs/btrfs-progs
-	optfeature "ipv6 support" net-dns/dnsmasq[ipv6]
-	optfeature "full incus-migrate support" net-misc/rsync
-	optfeature "lvm2 storage backend" sys-fs/lvm2
-	optfeature "zfs storage backend" sys-fs/zfs
-	elog
-	elog "Be sure to add your local user to the incus group."
-	elog
-}

sdk_container/src/third_party/portage-stable/app-containers/incus/incus-6.14-r1.ebuild

@@ -94,6 +94,8 @@ RESTRICT="test"
 
 GOPATH="${S}/_dist"
 
+PATCHES=( "${FILESDIR}"/incus-6.14-fix-qemu-memory-calculation-logic.patch )
+
 src_unpack() {
 	verify-sig_src_unpack
 	go-module_src_unpack