From 81174446a6c96097386e2d4830df2d7217c5655e Mon Sep 17 00:00:00 2001
From: Flatcar Buildbot <buildbot@flatcar-linux.org>
Date: Mon, 12 Jan 2026 07:10:35 +0000
Subject: [PATCH] app-containers/containers-common: Sync with Gentoo

It's from Gentoo commit 4f2ac103fee4e4604c57c46af22a8da04eaaa783.

Signed-off-by: Flatcar Buildbot <buildbot@flatcar-linux.org>
---
 .../app-containers/containers-common/Manifest |  1 +
 .../containers-common-0.64.2.ebuild           | 83 +++++++++++++++++++
 2 files changed, 84 insertions(+)
 create mode 100644 sdk_container/src/third_party/portage-stable/app-containers/containers-common/containers-common-0.64.2.ebuild

diff --git a/sdk_container/src/third_party/portage-stable/app-containers/containers-common/Manifest b/sdk_container/src/third_party/portage-stable/app-containers/containers-common/Manifest
index 92ba0fce8a..fe54370eff 100644
--- a/sdk_container/src/third_party/portage-stable/app-containers/containers-common/Manifest
+++ b/sdk_container/src/third_party/portage-stable/app-containers/containers-common/Manifest
@@ -1 +1,2 @@
 DIST containers-common-0.63.0.tar.gz 13516320 BLAKE2B f9d57d11210041065f2d5479d68d0318d5d49c634038f7db8601becc1c6bb801314a5aaacb6392f3f802ed8acde60284d78d49351ea8a8f9eaa3a3c449ba5727 SHA512 5d09a5d5fda8a3bafc2b1954b8b82cbc73747e9a088f220090d790cca203f330d0dbe45148a6ea2808448705506f4ff13ca05c85a2c2643cceff41cbe0f5ce9f
+DIST containers-common-0.64.2.tar.gz 13131015 BLAKE2B a4dc8484d9f1002c9e94a38396a767771df2260a15e371d20981db98d6ded7f563b4e25a2ff8f6912789264bfd4586826dd1821df2807f9c1d16baeab9601b8d SHA512 658044746d338de46b41577d7ae929b45b6de639dc33e671b2901527d9c069354fe586a7595ba514938fcedd9400c0ce47b10a3af92c4dc6aa29443d89a83ef5
diff --git a/sdk_container/src/third_party/portage-stable/app-containers/containers-common/containers-common-0.64.2.ebuild b/sdk_container/src/third_party/portage-stable/app-containers/containers-common/containers-common-0.64.2.ebuild
new file mode 100644
index 0000000000..d4f8c24462
--- /dev/null
+++ b/sdk_container/src/third_party/portage-stable/app-containers/containers-common/containers-common-0.64.2.ebuild
@@ -0,0 +1,83 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit readme.gentoo-r1
+
+DESCRIPTION="Common config files and docs for Containers stack"
+HOMEPAGE="https://github.com/containers/common"
+
+if [[ ${PV} == 9999* ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/containers/common.git"
+else
+	SRC_URI="https://github.com/containers/common/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+	S="${WORKDIR}/${P#containers-}"
+	KEYWORDS="~amd64 ~arm64 ~loong ~riscv"
+fi
+
+LICENSE="Apache-2.0"
+SLOT="0"
+RESTRICT="test"
+RDEPEND="
+	>=app-containers/aardvark-dns-1.12.0
+	>=app-containers/crun-1.17
+	>=app-containers/containers-image-5.32.0
+	>=app-containers/containers-storage-1.55.0
+	app-containers/containers-shortnames
+	>=app-containers/netavark-1.12.0
+	net-firewall/nftables
+	net-firewall/iptables[nftables]
+	>=net-misc/passt-2024.09.06
+	>=sys-fs/fuse-overlayfs-1.14
+"
+
+BDEPEND="
+	>=dev-go/go-md2man-2.0.3
+"
+
+PATCHES=(
+	"${FILESDIR}/examplify-mounts-conf.patch"
+)
+
+DOC_CONTENTS="\n
+For rootless operations, one needs to configure subuid(5) and subgid(5)\n
+See /etc/sub{uid,gid} to check whether rootless user is already configured\n
+If not, quickly configure it with:\n
+usermod --add-subuids 1065536-1131071 <rootless user>\n
+usermod --add-subgids 1065536-1131071 <rootless user>\n
+"
+
+src_prepare() {
+	default
+
+	[[ -f docs/Makefile && -f Makefile ]] || die
+	sed -i -e 's|/usr/local|/usr|g;' docs/Makefile Makefile || die
+}
+
+src_compile() {
+	emake docs
+	touch {images,layers}.lock || die
+}
+
+src_install() {
+	emake DESTDIR="${ED}" install
+	readme.gentoo_create_doc
+
+	insinto /usr/share/containers
+	doins pkg/seccomp/seccomp.json pkg/subscriptions/mounts.conf
+
+	keepdir /etc/containers/{certs.d,oci/hooks.d,networks,systemd} /var/lib/containers/sigstore \
+			/usr/lib/containers/storage
+	diropts -m0700
+	dodir /usr/lib/containers/storage/overlay-{images,layers}
+	for i in images layers; do
+		insinto /usr/lib/containers/storage/overlay-"${i}"
+		doins "${i}".lock
+	done
+}
+
+pkg_postinst() {
+	readme.gentoo_print_elog
+}