dev-libs/dbus-glib: Sync with Gentoo

It's from Gentoo commit 15726d5d34e2b8bbfd9bc1fb6b5635e92808e78c.

sdk_container/src/third_party/portage-stable/dev-libs/dbus-glib/Manifest

@@ -1 +1,2 @@
 DIST dbus-glib-0.112.tar.gz 715340 BLAKE2B 24e1c222f0116b32c109682816f6c35771647f4c63cab93a6621bd68b71ea4dca62fbf9e6bb360386b8658146dbf34b0d7dc471db7525585412d120340c4c969 SHA512 7c9f393f065dfb3d698f35e6554caf15fe539f5dd52d2b2bb6ed1770e130f5dab8e45379232520301455bae9bb77e25a109faf175153fcd4b9dd11d7de4a546e
+DIST dbus-glib-0.114.tar.gz 737791 BLAKE2B d9e9284d9dc9c57826a11d1776634102bf03e9d3cef98da96f92b9da936787eb4508258dc33ed3d35f0af8a39df8cff6e4b46ee0559319a50a33a0b1260d90d7 SHA512 c341cc0778edbf776d3e1a6d3cd9c136766544cb4b7239d6affa2fa246fa9c5716fe4d674c9bb56b36ee140344663bf967f70841ad132f978a662a22cc9a3a0d

sdk_container/src/third_party/portage-stable/dev-libs/dbus-glib/dbus-glib-0.112.ebuild

@@ -1,4 +1,4 @@
-# Copyright 1999-2024 Gentoo Authors
+# Copyright 1999-2025 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=7
@@ -46,6 +46,9 @@ multilib_src_configure() {
 	# bug #943768
 	append-cflags -std=gnu17
 
+	# bug #923801
+	append-lfs-flags
+
 	local myconf=(
 		--localstatedir="${EPREFIX}"/var
 		--enable-bash-completion

sdk_container/src/third_party/portage-stable/dev-libs/dbus-glib/dbus-glib-0.114.ebuild

@@ -0,0 +1,107 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit autotools bash-completion-r1 flag-o-matic multilib-minimal toolchain-funcs
+
+DESCRIPTION="D-Bus bindings for glib"
+HOMEPAGE="https://dbus.freedesktop.org/"
+SRC_URI="https://dbus.freedesktop.org/releases/${PN}/${P}.tar.gz"
+
+LICENSE="|| ( GPL-2 AFL-2.1 )"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos"
+IUSE="debug static-libs test"
+RESTRICT="!test? ( test )"
+
+DEPEND="
+	>=dev-libs/expat-2.1.0-r3[${MULTILIB_USEDEP}]
+	>=dev-libs/glib-2.40:2[${MULTILIB_USEDEP}]
+	>=sys-apps/dbus-1.8[${MULTILIB_USEDEP}]
+"
+RDEPEND="${DEPEND}"
+# CBUILD dependencies are needed to make a native tool while cross-compiling.
+BDEPEND="
+	>=dev-libs/expat-2.1.0-r3
+	>=dev-libs/glib-2.40:2
+	>=sys-apps/dbus-1.8
+	>=dev-util/glib-utils-2.40
+	>=dev-build/gtk-doc-am-1.14
+	virtual/pkgconfig
+"
+
+DOCS=( AUTHORS CONTRIBUTING.md NEWS README )
+
+set_TBD() {
+	# out of sources build dir for make check
+	export TBD="${BUILD_DIR}-tests"
+}
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+multilib_src_configure() {
+	# bug #923801
+	append-lfs-flags
+
+	local myconf=(
+		--localstatedir="${EPREFIX}"/var
+		--enable-bash-completion
+		--disable-gtk-doc
+		$(use_enable debug asserts)
+		$(use_enable static-libs static)
+	)
+
+	# Configure a CBUILD directory to make a native build tool.
+	if tc-is-cross-compiler; then
+		mkdir "${BUILD_DIR}-build" || die
+		cd "${BUILD_DIR}-build" || die
+		ECONF_SOURCE="${S}" econf_build
+		myconf+=( --with-dbus-binding-tool="$PWD/dbus/dbus-binding-tool" )
+		cd - || die
+	fi
+
+	ECONF_SOURCE="${S}" econf "${myconf[@]}"
+
+	ln -s "${S}"/doc/reference/html doc/reference/html || die #460042
+
+	if use test; then
+		set_TBD
+		mkdir "${TBD}" || die
+		cd "${TBD}" || die
+		einfo "Running configure in ${TBD}"
+		ECONF_SOURCE="${S}" econf \
+			"${myconf[@]}" \
+			$(use_enable test checks) \
+			$(use_enable test tests) \
+			$(use_enable test asserts)
+	fi
+}
+
+multilib_src_compile() {
+	tc-is-cross-compiler && emake -C "${BUILD_DIR}-build"
+
+	emake
+
+	if use test; then
+		set_TBD
+		emake -C "${TBD}"
+	fi
+}
+
+multilib_src_test() {
+	set_TBD
+	emake -C "${TBD}" check
+}
+
+multilib_src_install_all() {
+	einstalldocs
+
+	newbashcomp "${ED}"/etc/bash_completion.d/dbus-bash-completion.sh dbus-send
+	rm -r "${ED}"/etc/bash_completion.d || die
+
+	find "${ED}" -type f -name '*.la' -delete || die
+}

sdk_container/src/third_party/portage-stable/dev-libs/dbus-glib/metadata.xml

@@ -6,5 +6,6 @@
   </maintainer>
   <upstream>
     <remote-id type="cpe">cpe:/a:freedesktop:dbus-glib</remote-id>
+    <remote-id type="freedesktop-gitlab">dbus/dbus-glib</remote-id>
   </upstream>
 </pkgmetadata>