sys-block/parted: Sync with Gentoo

It's from Gentoo commit a480faba6b6162b018615e273d616f4d6a2e1c4e.

Signed-off-by: Flatcar Buildbot <buildbot@flatcar-linux.org>

sdk_container/src/third_party/portage-stable/sys-block/parted/Manifest

@@ -1,2 +1,4 @@
 DIST parted-3.6.tar.xz 1896164 BLAKE2B 99b6d096e4db05144c98e9f0a9a97c647aa911ee5df031244b03d5223f709d43d9302cef12dd4b2f97f42ec476510561b7f8b3b1ef7cb09d0a7c4d512e7a6739 SHA512 034a44b25718acba175212019d24f092972a791c5bd1d921ae91e17478657a77c5c5dd0c832bed7968c3a07ec6c65c0785acfac2f90c1ca5e1692f3c141693ef
 DIST parted-3.6.tar.xz.sig 508 BLAKE2B 92fbf624cfeb474e36d43954ecf6c42cf86557b99c7cd477c648bdeefb3ca2b40c51c320b20ea91075276d9ccc1da4219cd843b2916157c564c92a34a35ec55f SHA512 7c845026937b29fb49085ef9e3354226b73a1c3b5f9082d440d9a8ac13d76b1d07dae0bc10d8c974d4e57bc582f38c0a908e80718dd1ff1adfad3b04699c672c
+DIST parted-3.7.tar.xz 1970028 BLAKE2B 967a2c5e6f8d93bd8eff2fe9092413582437c7d33fb151ca5230c8acd0c32e94c90edcb83abed888da560f7fbfcc77ee31cda54ddc3c1af24b1a1c522ab83bca SHA512 941afeb68edb45c33fb797f4c320ed1aa1de2e8b35defa5d742aa6894618e6729a1440e3ee0824e8710bc58eb42b85d77f28ba083d92d4ea3f3f65f37c8307b0
+DIST parted-3.7.tar.xz.sig 508 BLAKE2B 006bb49ee8ff9135e633bfa6c2a32fcd9f661e83cab58e85535adcac3481350a6c552a730b5b32abca41a8a9f953f85bc48abd5a24d05e6048bd1f5a8dd3efc1 SHA512 b6cb75d0e58ea344b91e8b92aba40de1d828257b123134052a9aafaaad5ed0f1aec2e11c2ea17776ea30800636d823aa2da0044be52c9c5addf4b102caafc25c

sdk_container/src/third_party/portage-stable/sys-block/parted/parted-3.6-r2.ebuild

@@ -1,4 +1,4 @@
-# Copyright 1999-2025 Gentoo Authors
+# Copyright 1999-2026 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=7
@@ -17,7 +17,7 @@ SRC_URI="
 LICENSE="GPL-3+"
 SLOT="0"
 KEYWORDS="~alpha amd64 arm arm64 ~hppa ~loong ~mips ppc ppc64 ~riscv ~s390 ~sparc x86"
-IUSE="+debug device-mapper nls readline"
+IUSE="+debug device-mapper nls readline static-libs"
 
 # util-linux for libuuid
 RDEPEND="
@@ -75,9 +75,9 @@ src_configure() {
 		$(use_enable debug)
 		$(use_enable device-mapper)
 		$(use_enable nls)
+		$(use_enable static-libs static)
 		$(use_with readline)
 		--disable-rpath
-		--disable-static
 	)
 	econf "${myconf[@]}"
 }

sdk_container/src/third_party/portage-stable/sys-block/parted/parted-3.7.ebuild

@@ -0,0 +1,85 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+VERIFY_SIG_OPENPGP_KEY_PATH=/usr/share/openpgp-keys/bcl.asc
+
+inherit verify-sig
+
+DESCRIPTION="Create, destroy, resize, check, copy partitions and file systems"
+HOMEPAGE="https://www.gnu.org/software/parted/"
+SRC_URI="
+	mirror://gnu/${PN}/${P}.tar.xz
+	verify-sig? ( mirror://gnu/${PN}/${P}.tar.xz.sig )
+"
+
+LICENSE="GPL-3+"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+IUSE="+debug device-mapper nls readline static-libs"
+
+# util-linux for libuuid
+RDEPEND="
+	>=sys-fs/e2fsprogs-1.27
+	sys-apps/util-linux
+	device-mapper? ( >=sys-fs/lvm2-2.02.45 )
+	readline? (
+		>=sys-libs/ncurses-5.7-r7:0=
+		>=sys-libs/readline-5.2:0=
+	)
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	nls? ( >=sys-devel/gettext-0.12.1-r2 )
+	verify-sig? ( >=sec-keys/openpgp-keys-bcl-20260418 )
+	virtual/pkgconfig
+"
+
+DOCS=(
+	AUTHORS BUGS ChangeLog NEWS README THANKS TODO doc/{API.md,FAT,USER.jp}
+)
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-3.2-po4a-mandir.patch
+	# https://lists.gnu.org/archive/html/bug-parted/2022-02/msg00000.html
+	"${FILESDIR}"/${PN}-3.4-posix-printf.patch
+	# https://debbugs.gnu.org/61129
+	"${FILESDIR}"/${PN}-3.6-tests-unicode.patch
+)
+
+# false positive
+QA_CONFIG_IMPL_DECL_SKIP="MIN"
+
+src_prepare() {
+	default
+
+	touch doc/pt_BR/Makefile.in || die
+}
+
+src_configure() {
+	# -fanalyzer substantially slows down the build and isn't useful for
+	# us. It's useful for upstream as it's static analysis, but it's not
+	# useful when just getting something built.
+	export gl_cv_warn_c__fanalyzer=no
+
+	local myconf=(
+		$(use_enable debug)
+		$(use_enable device-mapper)
+		$(use_enable nls)
+		$(use_enable static-libs static)
+		$(use_with readline)
+		--disable-rpath
+		# Avoid clobbering _FORTIFY_SOURCE
+		--disable-gcc-warnings
+	)
+
+	# https://debbugs.gnu.org/61128
+	CONFIG_SHELL="${BROOT}"/bin/bash econf "${myconf[@]}"
+}
+
+src_install() {
+	default
+
+	find "${ED}" -type f -name '*.la' -delete || die
+}