mirrors/flatcar-scripts
1
0
Fork 0
mirror of https://github.com/flatcar/scripts.git synced 2025-08-09 22:16:58 +02:00
Code Issues Packages Projects Releases Wiki Activity

net-libs/libpcap: Sync with Gentoo

Browse Source 
It's from Gentoo commit 7eb1712e23c240b50f1e072a589a843abb574f7d.
This commit is contained in:
Flatcar Buildbot 2024-09-02 07:18:44 +00:00 committed by Krzesimir Nowak
parent 363b44823b
commit 70a8987b3b
4 changed files with 107 additions and 5 deletions
Show Stats Download Patch File Download Diff File Expand all files Collapse all files

2
sdk_container/src/third_party/portage-stable/net-libs/libpcap/Manifest vendored
View File

@ -1,2 +1,4 @@
DIST libpcap-1.10.4.tar.gz 952153 BLAKE2B 05a7eafc1e1817f7844008db89d8fb10cd2525c22f7ee6c9e3d582b14229412f38ccced5e9d80a96dd459ef9eab12eccb5c1dd4978ddc9f66267469212005e4c SHA512 1f6d6ddd07dae7c557054cb246437ecdaf39d579592a5a6bdf1144eea6cb5a779ac4ca647cfed11ec1b0bb18efc63b845444e497070bacefaaed19a5787ae5e1
DIST libpcap-1.10.4.tar.gz.sig 442 BLAKE2B d0eb5da9a57003848b24d458e50a201d0bb8876a12e63f6627bf9dc1a784e780610cd0c858243cc75a63999b40bc64507b078777ae844ede7c07eef9f4f9e0d5 SHA512 34aa401c2e162d708c61b78b445af2fe4ddc0e57de9124b5cc3a05679ffbc3834088160f83892d827e25c65b33313fe71aa73c2de09935d387252ab315ca5ee1
DIST libpcap-1.10.5.tar.gz 974772 BLAKE2B c0bb29c5c308cb21244a9c63d3daa19033eb21fbd721607c057f04b2ae6b2527fb1cfeeb2b29b7c3535d5d6256aa5fdf5aa22ce48aa4f88a3cc8a81029a98116 SHA512 e599a31f2f1c03bdf386defa613ea9f08f80459c87068c2dd36c55c1bd678e2622cdce6333f0a776f16812df7bd4d6747820d1c35c7a2f1d7ad4a2ffb45dbe24
DIST libpcap-1.10.5.tar.gz.sig 442 BLAKE2B 6816bb76c6b41b292a29edcff7d89e71511d25190da7e4f26296fbae2690e476b5072f44b5ff1c9e43f31403a37e23d69c18e1f2483488fe8d742cbe3f768312 SHA512 183ed0f6a93679550dc5a589422e92023a92be8fe29f79fb296e966f26e3693e1c6d47c5e88bccbb6004cb19b6419c9d7cd998f4e2255f5594a7f5f6e84ecdc9

7
sdk_container/src/third_party/portage-stable/net-libs/libpcap/libpcap-1.10.4.ebuild vendored
View File

@ -1,4 +1,4 @@
# Copyright 1999-2023 Gentoo Authors
# Copyright 1999-2024 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
@ -21,7 +21,10 @@ else
KEYWORDS="~alpha amd64 arm arm64 hppa ~ia64 ~loong ~m68k ~mips ppc ppc64 ~riscv ~s390 sparc x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos"
fi
LICENSE="BSD"
# The project itself has COPYING with BSD, but the files used for
# the libpcap library itself seem to be a mix of BSD-with-attribution
# and BSD-4.
LICENSE="BSD BSD-with-attribution BSD-4"
SLOT="0"
IUSE="bluetooth dbus netlink rdma remote static-libs test usb yydebug"
RESTRICT="!test? ( test )"

94
sdk_container/src/third_party/portage-stable/net-libs/libpcap/libpcap-1.10.5.ebuild vendored Normal file
View File

@ -0,0 +1,94 @@
# Copyright 1999-2024 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
inherit autotools multilib-minimal
DESCRIPTION="A system-independent library for user-level network packet capture"
HOMEPAGE="https://www.tcpdump.org/ https://github.com/the-tcpdump-group/libpcap"
if [[ ${PV} == *9999* ]] ; then
EGIT_REPO_URI="https://github.com/the-tcpdump-group/libpcap"
inherit git-r3
else
VERIFY_SIG_OPENPGP_KEY_PATH=/usr/share/openpgp-keys/tcpdump.asc
inherit verify-sig
SRC_URI="https://www.tcpdump.org/release/${P}.tar.gz"
SRC_URI+=" verify-sig? ( https://www.tcpdump.org/release/${P}.tar.gz.sig )"
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos"
fi
# The project itself has COPYING with BSD, but the files used for
# the libpcap library itself seem to be a mix of BSD-with-attribution
# and BSD-4.
LICENSE="BSD BSD-with-attribution BSD-4"
SLOT="0"
IUSE="bluetooth dbus netlink rdma remote static-libs test usb yydebug"
RESTRICT="!test? ( test )"
RDEPEND="
bluetooth? ( net-wireless/bluez:=[${MULTILIB_USEDEP}] )
dbus? ( sys-apps/dbus[${MULTILIB_USEDEP}] )
netlink? ( dev-libs/libnl:3[${MULTILIB_USEDEP}] )
remote? ( virtual/libcrypt:=[${MULTILIB_USEDEP}] )
rdma? ( sys-cluster/rdma-core )
usb? ( virtual/libusb:1[${MULTILIB_USEDEP}] )
"
DEPEND="${RDEPEND}"
BDEPEND="
app-alternatives/yacc
sys-devel/flex
dbus? ( virtual/pkgconfig )
"
if [[ ${PV} != *9999* ]] ; then
BDEPEND+=" verify-sig? ( >=sec-keys/openpgp-keys-tcpdump-20240901 )"
fi
src_prepare() {
default
if ! [[ -f VERSION ]]; then
echo ${PV} > VERSION || die
fi
eautoreconf
}
multilib_src_configure() {
# bug #884275
export LEX=flex
ECONF_SOURCE="${S}" econf \
$(use_enable bluetooth) \
$(use_enable dbus) \
$(use_enable rdma) \
$(use_enable remote) \
$(use_enable usb) \
$(use_enable yydebug) \
$(use_with netlink libnl) \
--enable-ipv6
}
multilib_src_compile() {
emake all shared
use test && emake testprogs
}
multilib_src_test() {
testprogs/findalldevstest || die
}
multilib_src_install_all() {
dodoc CREDITS CHANGES VERSION TODO README.* doc/README.*
# remove static libraries (--disable-static does not work)
if ! use static-libs; then
find "${ED}" -name '*.a' -exec rm {} + || die
fi
find "${ED}" -name '*.la' -delete || die
}

9
sdk_container/src/third_party/portage-stable/net-libs/libpcap/libpcap-9999.ebuild vendored
View File

@ -1,4 +1,4 @@
# Copyright 1999-2023 Gentoo Authors
# Copyright 1999-2024 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
@ -21,7 +21,10 @@ else
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos"
fi
LICENSE="BSD"
# The project itself has COPYING with BSD, but the files used for
# the libpcap library itself seem to be a mix of BSD-with-attribution
# and BSD-4.
LICENSE="BSD BSD-with-attribution BSD-4"
SLOT="0"
IUSE="bluetooth dbus netlink rdma remote static-libs test usb yydebug"
RESTRICT="!test? ( test )"
@ -42,7 +45,7 @@ BDEPEND="
"
if [[ ${PV} != *9999* ]] ; then
BDEPEND+=" verify-sig? ( sec-keys/openpgp-keys-tcpdump )"
BDEPEND+=" verify-sig? ( >=sec-keys/openpgp-keys-tcpdump-20240901 )"
fi
src_prepare() {