app-portage/portage-utils: Sync with Gentoo

It's from Gentoo commit 8616ac9fa23c6cfb013673c339832fc07b39d6df.

sdk_container/src/third_party/portage-stable/app-portage/portage-utils/Manifest

@@ -1,3 +1,4 @@
 DIST portage-utils-0.95.tar.xz 1806140 BLAKE2B 5a468a7b4006073203ba634a5d70398e254ef5db7e9b71fbcf20bce68942f74acce1d42b5d315931f93e8698c8dd2f38f328fcc6fdaa86addba7dbcc21fce5fa SHA512 2d1f4b986a377249043259d8ada1a35a7dd55179f0ef5c2c18a4180c8f1f7064133ab2677426098e61b1355fa26cb0f8aa3c6ea06d46af4c4ba2df4eb53489a4
 DIST portage-utils-0.96.1.tar.xz 1807156 BLAKE2B 6bf334c0083e5e8b0d6206ff43d4df0e32a9576ddedbe055cb6ef903b5f11d0878512ace7f93ea37207181321ca160a8f721b3095b2bcbfcdbb353ba3f5d4873 SHA512 769e734e0738aa52408fd6c151706085148818a19b2ad1051684e2d54fe9f486f2e3a25e8fb408c83325cfb428644c6c0aa3b6d1bac0d2189680c70d9657bcbf
 DIST portage-utils-0.96.tar.xz 1806032 BLAKE2B 93ef9658a4b0bae7fb0527462bd9d0d19f396262818380d8ec2022c9fda596265c50adc262bdf296a4dd8c6b891b064316281d21444c8b903db20ca2463879e3 SHA512 cc32f53532c082544cabe505d8b90b947b6ab48742678aa98cbe9ba291625e8449ed0ecd90e01dc00b06c209b34001ad57a060918658e53d3babdc5c76ea7b02
+DIST portage-utils-0.97.tar.xz 1861616 BLAKE2B bdb4c6c1260a00304fb2c659629e0ddd4ca0378b1a060ea8b1f02ecb6060b4101c6e8984a6befd8b831a2b415fcdc5a51b6dac2fb203b36585f4a7d389ea0913 SHA512 f0f9ecf87df6e08b7f7dbdfe758c1a585a6836478d3adbcecdc2e33c9cfd78a5a10ae3090f0aa5ad0fa8a1eff88bf9e512d861b46bc77e5a536b46a3b36cd466

sdk_container/src/third_party/portage-stable/app-portage/portage-utils/portage-utils-0.97.ebuild

@@ -0,0 +1,70 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit flag-o-matic toolchain-funcs
+
+DESCRIPTION="Small and fast Portage helper tools written in C"
+HOMEPAGE="https://wiki.gentoo.org/wiki/Portage-utils"
+
+if [[ ${PV} == *9999 ]]; then
+	inherit git-r3 autotools
+	EGIT_REPO_URI="https://anongit.gentoo.org/git/proj/portage-utils.git"
+else
+	SRC_URI="https://dev.gentoo.org/~grobian/distfiles/${P}.tar.xz"
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~arm64-macos ~ppc-macos ~x64-macos ~x64-solaris"
+fi
+
+LICENSE="GPL-2"
+SLOT="0"
+IUSE="openmp +qmanifest static"
+
+RDEPEND="
+	openmp? ( || (
+		sys-devel/gcc:*[openmp]
+		sys-libs/libomp
+	) )
+	qmanifest? (
+		!static? (
+			app-crypt/gpgme:=
+			app-crypt/libb2:=
+			sys-libs/zlib:=
+		)
+	)"
+DEPEND="${RDEPEND}
+	qmanifest? (
+		static? (
+			app-crypt/gpgme[static-libs]
+			app-crypt/libb2[static-libs]
+			sys-libs/zlib[static-libs]
+		)
+	)"
+BDEPEND="virtual/pkgconfig"
+
+# bug #898362, gnulib explicit checks
+QA_CONFIG_IMPL_DECL_SKIP=(
+	"MIN"
+	"unreachable"
+	"alignof"
+	"static_assert"
+)
+
+pkg_setup() {
+	[[ ${MERGE_TYPE} != binary ]] && use openmp && tc-check-openmp
+}
+
+src_prepare() {
+	default
+	[[ ${PV} == *9999 ]] && eautoreconf
+}
+
+src_configure() {
+	use static && append-ldflags -static
+
+	econf \
+		--disable-maintainer-mode \
+		--with-eprefix="${EPREFIX}" \
+		$(use_enable qmanifest) \
+		$(use_enable openmp)
+}

sdk_container/src/third_party/portage-stable/app-portage/portage-utils/portage-utils-9999.ebuild

@@ -1,4 +1,4 @@
-# Copyright 1999-2023 Gentoo Authors
+# Copyright 1999-2025 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=8
@@ -18,7 +18,7 @@ fi
 
 LICENSE="GPL-2"
 SLOT="0"
-IUSE="openmp +qmanifest +qtegrity static"
+IUSE="openmp +qmanifest static"
 
 RDEPEND="
 	openmp? ( || (
@@ -29,33 +29,26 @@ RDEPEND="
 		!static? (
 			app-crypt/gpgme:=
 			app-crypt/libb2:=
-			dev-libs/openssl:=
 			sys-libs/zlib:=
 		)
-	)
-	qtegrity? (
-		!static? (
-			dev-libs/openssl:=
-		)
 	)"
 DEPEND="${RDEPEND}
 	qmanifest? (
 		static? (
 			app-crypt/gpgme[static-libs]
 			app-crypt/libb2[static-libs]
-			dev-libs/openssl[static-libs]
 			sys-libs/zlib[static-libs]
 		)
-	)
-	qtegrity? (
-		static? (
-			dev-libs/openssl[static-libs]
-		)
 	)"
 BDEPEND="virtual/pkgconfig"
 
-# bug #898362, gnulib check explicitly looks for MIN in some headers
+# bug #898362, gnulib explicit checks
-QA_CONFIG_IMPL_DECL_SKIP="MIN"
+QA_CONFIG_IMPL_DECL_SKIP=(
+	"MIN"
+	"unreachable"
+	"alignof"
+	"static_assert"
+)
 
 pkg_setup() {
 	[[ ${MERGE_TYPE} != binary ]] && use openmp && tc-check-openmp
@@ -73,6 +66,5 @@ src_configure() {
 		--disable-maintainer-mode \
 		--with-eprefix="${EPREFIX}" \
 		$(use_enable qmanifest) \
-		$(use_enable qtegrity) \
 		$(use_enable openmp)
 }