Copied linux-headers-2.6.30-r1.ebuild to portage-stable overlay and added linux-headers-2.6.38.ebuild.

Copied linux-headers-2.6.30-r1.ebuild to portage-stable overlay, so
that we upgrade to the new linux-headers without crossdev complaining.
Also added linux-headers-2.6.38.ebuild from upstream portage.

BUG=chromium-os:15872
TEST=Ran setup_board --nousepkg and checked that crossdev correctly
still uses the 2.6.30-r1 ebuild.

Change-Id: I7904c7db2b7d220f155d236a64fb0da4812bf3dc
Reviewed-on: http://gerrit.chromium.org/gerrit/1850
Reviewed-by: Scott James Remnant <keybuk@chromium.org>
Reviewed-by: David James <davidjames@chromium.org>
Tested-by: Raymes Khoury <raymes@chromium.org>

sdk_container/src/third_party/portage-stable/sys-kernel/linux-headers/linux-headers-2.6.30-r1.ebuild

@@ -0,0 +1,50 @@
+# Copyright 1999-2010 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/sys-kernel/linux-headers/linux-headers-2.6.30-r1.ebuild,v 1.11 2010/03/07 22:47:34 maekke Exp $
+
+ETYPE="headers"
+H_SUPPORTEDARCH="alpha amd64 arm bfin cris hppa m68k mips ia64 ppc ppc64 s390 sh sparc x86"
+inherit kernel-2
+detect_version
+
+PATCH_VER="2"
+SRC_URI="mirror://gentoo/gentoo-headers-base-${PV}.tar.lzma"
+[[ -n ${PATCH_VER} ]] && SRC_URI="${SRC_URI} mirror://gentoo/gentoo-headers-${PV}-${PATCH_VER}.tar.lzma"
+
+KEYWORDS="-* alpha amd64 arm hppa ~ia64 ~m68k -mips ppc ppc64 ~s390 -sh ~sparc x86 ~amd64-linux ~x86-linux"
+
+DEPEND="|| ( app-arch/xz-utils app-arch/lzma-utils )"
+RDEPEND=""
+
+S=${WORKDIR}/gentoo-headers-base-${PV}
+
+src_unpack() {
+	unpack ${A}
+	cd "${S}"
+	[[ -n ${PATCH_VER} ]] && EPATCH_SUFFIX="patch" epatch "${WORKDIR}"/${PV}
+	# workaround #244640
+	mkdir arch/sparc64
+	touch arch/sparc64/Makefile
+}
+
+src_install() {
+	kernel-2_src_install
+	cd "${D}"
+	egrep -r \
+		-e '(^|[[:space:](])(asm|volatile|inline)[[:space:](]' \
+		-e '\<([us](8|16|32|64))\>' \
+		.
+	headers___fix $(find -type f)
+
+	egrep -l -r -e '__[us](8|16|32|64)' "${D}" | xargs grep -L linux/types.h
+
+	# hrm, build system sucks
+	find "${D}" '(' -name '.install' -o -name '*.cmd' ')' -print0 | xargs -0 rm -f
+
+	# provided by libdrm (for now?)
+	rm -rf "${D}"/$(kernel_header_destdir)/drm
+}
+
+src_test() {
+	emake ARCH=$(tc-arch-kernel) headers_check || die
+}

sdk_container/src/third_party/portage-stable/sys-kernel/linux-headers/linux-headers-2.6.38.ebuild

@@ -0,0 +1,49 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/sys-kernel/linux-headers/linux-headers-2.6.38.ebuild,v 1.1 2011/03/18 19:49:01 vapier Exp $
+
+EAPI="3"
+
+ETYPE="headers"
+H_SUPPORTEDARCH="alpha amd64 arm bfin cris hppa m68k mips ia64 ppc ppc64 s390 sh sparc x86"
+inherit kernel-2
+detect_version
+
+PATCH_VER="1"
+SRC_URI="mirror://gentoo/gentoo-headers-base-${PV}.tar.xz"
+[[ -n ${PATCH_VER} ]] && SRC_URI="${SRC_URI} mirror://gentoo/gentoo-headers-${PV%.1}-${PATCH_VER}.tar.xz"
+
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-linux ~x86-linux"
+
+DEPEND="app-arch/xz-utils"
+RDEPEND=""
+
+S=${WORKDIR}/gentoo-headers-base-${PV}
+
+src_unpack() {
+	unpack ${A}
+	cd "${S}"
+	[[ -n ${PATCH_VER} ]] && EPATCH_SUFFIX="patch" epatch "${WORKDIR}"/${PV%.1}
+}
+
+src_install() {
+	kernel-2_src_install
+	cd "${D}"
+	egrep -r \
+		-e '(^|[[:space:](])(asm|volatile|inline)[[:space:](]' \
+		-e '\<([us](8|16|32|64))\>' \
+		.
+	headers___fix $(find -type f)
+
+	egrep -l -r -e '__[us](8|16|32|64)' "${D}" | xargs grep -L linux/types.h
+
+	# hrm, build system sucks
+	find "${D}" '(' -name '.install' -o -name '*.cmd' ')' -print0 | xargs -0 rm -f
+
+	# provided by libdrm (for now?)
+	rm -rf "${D}"/$(kernel_header_destdir)/drm
+}
+
+src_test() {
+	emake ARCH=$(tc-arch-kernel) headers_check || die
+}