app-portage/gentoolkit: Sync with Gentoo

It's from Gentoo commit 122ee4d7e65a6a1ba60a508a99f4d93632bda5dd.

sdk_container/src/third_party/portage-stable/app-portage/gentoolkit/Manifest

@@ -1,2 +1,3 @@
 DIST gentoolkit-0.6.1.tar.gz 3195781 BLAKE2B 27e370de77586b375dc70caa1abba4c2bc4207e8f08e0a7ea2953097135506949db71ff9102a0ead198e4dea425440c57b94ac7a811ca2d5e0016fc7e234bb0d SHA512 1ffc466b69a9c53f1bbd40f6f4d1eb33d5f0f4287bb65ba1a7b1b2675ad61ecffa55ed9fda7c1ae8148744f0a77e224315eb1903dfd61a2a3dab1600fc672d2d
 DIST gentoolkit-0.6.2.tar.bz2 3186974 BLAKE2B 48f388962e70842b7959467b7697b98121ee2a27bca6e2fc2ebb69782ece1df9b63b4451e19ebacf5a627a9c6feb17f7af395229d2eb870d8bbde1da80262593 SHA512 a1c9157758453f214e6131237df2bc91c49c28a4411ecbb0f74768ae0dd7c4fe8272cfc354a424f6acc8cc322d4eaa35ef98147fe749bc41cb680bb3acfdc2ac
+DIST gentoolkit-0.6.3.tar.bz2 3186163 BLAKE2B 0f9befac53faa2b578b461a55c7113934a60478fc5d8d5ab0e06cb836ff5a2de75bb290ed797a2b085ec9f33c8494e3c3d5d0d6b643c525fff4dd0a82657118f SHA512 cf51480213fd4bac45d44f5eb5e4be4cb5c5b97ad63ecd832eb54fc7043ab8e974491005431f0897d6c41d251ae0f9fc95cfdfc4d613fc56340630a094bfc61d

sdk_container/src/third_party/portage-stable/app-portage/gentoolkit/gentoolkit-0.6.3.ebuild

@@ -0,0 +1,121 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..12} pypy3 )
+PYTHON_REQ_USE="xml(+),threads(+)"
+
+inherit meson python-r1 tmpfiles
+
+if [[ ${PV} = 9999* ]]; then
+	EGIT_REPO_URI="https://anongit.gentoo.org/git/proj/gentoolkit.git"
+	inherit git-r3
+else
+	SRC_URI="https://gitweb.gentoo.org/proj/gentoolkit.git/snapshot/${P}.tar.bz2"
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~arm64-macos ~ppc-macos ~x64-macos ~x64-solaris"
+fi
+
+DESCRIPTION="Collection of administration scripts for Gentoo"
+HOMEPAGE="https://wiki.gentoo.org/wiki/Project:Portage-Tools"
+
+LICENSE="GPL-2"
+SLOT="0"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+# Need newer Portage for eclean-pkg API, bug #900224
+DEPEND="
+	>=sys-apps/portage-3.0.53[${PYTHON_USEDEP}]
+"
+RDEPEND="
+	${DEPEND}
+	${PYTHON_DEPS}
+	app-alternatives/awk
+	sys-apps/gentoo-functions
+"
+
+# setuptools is still needed as a workaround for Python 3.12+ for now.
+# https://github.com/mesonbuild/meson/issues/7702
+#
+# >=meson-1.2.1-r1 for bug #912051
+BDEPEND="
+	${PYTHON_DEPS}
+	>=dev-util/meson-1.2.1-r1
+	$(python_gen_cond_dep '
+		dev-python/setuptools[${PYTHON_USEDEP}]
+	' python3_12)
+"
+
+src_prepare() {
+	default
+	if use prefix-guest ; then
+		# use correct repo name, bug #632223
+		sed -i \
+			-e "/load_profile_data/s/repo='gentoo'/repo='gentoo_prefix'/" \
+			pym/gentoolkit/profile.py || die
+	fi
+}
+
+src_configure() {
+	local code_only=false
+	python_foreach_impl my_src_configure
+}
+
+my_src_configure() {
+	local emesonargs=(
+		-Dcode-only=${code_only}
+		-Deprefix="${EPREFIX}"
+		-Ddocdir="${EPREFIX}/usr/share/doc/${PF}"
+	)
+
+	meson_src_configure
+	code_only=true
+}
+
+src_compile() {
+	python_foreach_impl meson_src_compile
+}
+
+src_test() {
+	python_foreach_impl meson_src_test --no-rebuild --verbose
+}
+
+src_install() {
+	python_foreach_impl my_src_install
+	dotmpfiles data/tmpfiles.d/revdep-rebuild.conf
+
+	local scripts
+	mapfile -t scripts < <(awk '/^#!.*python/ {print FILENAME} {nextfile}' "${ED}"/usr/bin/* || die)
+	python_replicate_script "${scripts[@]}"
+}
+
+my_src_install() {
+	local pydirs=(
+		"${D}$(python_get_sitedir)"
+	)
+
+	meson_src_install
+	python_optimize "${pydirs[@]}"
+	python_fix_shebang "${pydirs[@]}"
+}
+
+pkg_postinst() {
+	tmpfiles_process revdep-rebuild.conf
+
+	# Only show the elog information on a new install
+	if [[ ! ${REPLACING_VERSIONS} ]]; then
+		elog
+		elog "For further information on gentoolkit, please read the gentoolkit"
+		elog "guide: https://wiki.gentoo.org/wiki/Gentoolkit"
+		elog
+		elog "Another alternative to equery is app-portage/portage-utils"
+		elog
+		elog "Additional tools that may be of interest:"
+		elog
+		elog "    app-admin/eclean-kernel"
+		elog "    app-portage/diffmask"
+		elog "    app-portage/flaggie"
+		elog "    app-portage/portpeek"
+		elog "    app-portage/smart-live-rebuild"
+	fi
+}

sdk_container/src/third_party/portage-stable/app-portage/gentoolkit/gentoolkit-9999.ebuild

@@ -12,8 +12,8 @@ if [[ ${PV} = 9999* ]]; then
 	EGIT_REPO_URI="https://anongit.gentoo.org/git/proj/gentoolkit.git"
 	inherit git-r3
 else
-	SRC_URI="https://gitweb.gentoo.org/proj/gentoolkit.git/snapshot/${P}.tar.gz"
+	SRC_URI="https://gitweb.gentoo.org/proj/gentoolkit.git/snapshot/${P}.tar.bz2"
-	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 sparc ~x86 ~amd64-linux ~x86-linux ~arm64-macos ~ppc-macos ~x64-macos ~x64-solaris"
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~arm64-macos ~ppc-macos ~x64-macos ~x64-solaris"
 fi
 
 DESCRIPTION="Collection of administration scripts for Gentoo"
@@ -25,7 +25,7 @@ REQUIRED_USE="${PYTHON_REQUIRED_USE}"
 
 # Need newer Portage for eclean-pkg API, bug #900224
 DEPEND="
-	>=sys-apps/portage-3.0.52[${PYTHON_USEDEP}]
+	>=sys-apps/portage-3.0.53[${PYTHON_USEDEP}]
 "
 RDEPEND="
 	${DEPEND}