Newly-introduced vanilla ebuilds from chromiumos-overlay

BUG=none
TEST=./build_packages for x86-generic and arm-generic

Change-Id: I51244c981f4e31d556d30d5cec3e70b05e784b3b
Reviewed-on: http://gerrit.chromium.org/gerrit/6731
Reviewed-by: David James <davidjames@chromium.org>
Tested-by: Diego Elio Pettenò <flameeyes@chromium.org>

sdk_container/src/third_party/portage-stable/sys-devel/gdb/gdb-7.1.ebuild

@@ -1,103 +0,0 @@
-# Copyright 1999-2010 Gentoo Foundation
-# Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/sys-devel/gdb/gdb-7.1.ebuild,v 1.1 2010/03/19 02:21:14 vapier Exp $
-
-inherit flag-o-matic eutils
-
-export CTARGET=${CTARGET:-${CHOST}}
-if [[ ${CTARGET} == ${CHOST} ]] ; then
-	if [[ ${CATEGORY/cross-} != ${CATEGORY} ]] ; then
-		export CTARGET=${CATEGORY/cross-}
-	fi
-fi
-is_cross() { [[ ${CHOST} != ${CTARGET} ]] ; }
-
-PATCH_VER="1"
-DESCRIPTION="GNU debugger"
-HOMEPAGE="http://sources.redhat.com/gdb/"
-SRC_URI="http://ftp.gnu.org/gnu/gdb/${P}.tar.bz2
-	ftp://sources.redhat.com/pub/gdb/releases/${P}.tar.bz2
-	${PATCH_VER:+mirror://gentoo/${P}-patches-${PATCH_VER}.tar.lzma}"
-
-LICENSE="GPL-2 LGPL-2"
-is_cross \
-	&& SLOT="${CTARGET}" \
-	|| SLOT="0"
-KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sparc ~x86 ~x86-fbsd"
-IUSE="expat multitarget nls python test vanilla"
-
-RDEPEND=">=sys-libs/ncurses-5.2-r2
-	sys-libs/readline
-	expat? ( dev-libs/expat )
-	python? ( dev-lang/python )"
-DEPEND="${RDEPEND}
-	|| ( app-arch/xz-utils app-arch/lzma-utils )
-	test? ( dev-util/dejagnu )
-	nls? ( sys-devel/gettext )"
-
-src_unpack() {
-	unpack ${A}
-	cd "${S}"
-	use vanilla || [[ -n ${PATCH_VER} ]] && EPATCH_SUFFIX="patch" epatch "${WORKDIR}"/patch
-	strip-linguas -u bfd/po opcodes/po
-}
-
-gdb_branding() {
-	printf "Gentoo ${PV} "
-	if [[ -n ${PATCH_VER} ]] ; then
-		printf "p${PATCH_VER}"
-	else
-		printf "vanilla"
-	fi
-}
-
-src_compile() {
-	strip-unsupported-flags
-	econf \
-		--with-pkgversion="$(gdb_branding)" \
-		--with-bugurl='http://bugs.gentoo.org/' \
-		--disable-werror \
-		$(has_version '=sys-libs/readline-5*:0' && echo --with-system-readline) \
-		$(is_cross && echo --with-sysroot=/usr/${CTARGET}) \
-		$(use_with expat) \
-		$(use_enable nls) \
-		$(use multitarget && echo --enable-targets=all) \
-		$(use_with python) \
-		|| die
-	emake || die
-}
-
-src_test() {
-	emake check || ewarn "tests failed"
-}
-
-src_install() {
-	emake \
-		DESTDIR="${D}" \
-		libdir=/nukeme/pretty/pretty/please includedir=/nukeme/pretty/pretty/please \
-		install || die
-	rm -r "${D}"/nukeme || die
-
-	# Don't install docs when building a cross-gdb
-	if [[ ${CTARGET} != ${CHOST} ]] ; then
-		rm -r "${D}"/usr/share
-		return 0
-	fi
-
-	dodoc README
-	docinto gdb
-	dodoc gdb/CONTRIBUTE gdb/README gdb/MAINTAINERS \
-		gdb/NEWS gdb/ChangeLog gdb/PROBLEMS
-	docinto sim
-	dodoc sim/ChangeLog sim/MAINTAINERS sim/README-HACKING
-
-	dodoc "${WORKDIR}"/extra/gdbinit.sample
-
-	# Remove shared info pages
-	rm -f "${D}"/usr/share/info/{annotate,bfd,configure,standards}.info*
-}
-
-pkg_postinst() {
-	# portage sucks and doesnt unmerge files in /etc
-	rm -vf "${ROOT}"/etc/skel/.gdbinit
-}

sdk_container/src/third_party/portage-stable/sys-fs/avfs/avfs-1.0.0.ebuild

@@ -0,0 +1,65 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/sys-fs/avfs/avfs-1.0.0.ebuild,v 1.1 2011/07/12 00:31:58 radhermit Exp $
+
+EAPI=4
+inherit eutils
+
+DESCRIPTION="AVFS is a virtual filesystem that allows browsing of compressed files."
+HOMEPAGE="http://sourceforge.net/projects/avf"
+SRC_URI="mirror://sourceforge/avf/${P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~hppa ~ppc ~ppc64 ~x86"
+IUSE="static-libs +lzma"
+
+DEPEND=">=sys-fs/fuse-2.4
+	sys-libs/zlib
+	app-arch/bzip2
+	lzma? ( app-arch/xz-utils )"
+RDEPEND="${DEPEND}"
+
+src_prepare() {
+	# Fixes bug #258295
+	epatch "${FILESDIR}/${PN}-0.9.8-gcc43_fix_open_missing_mode.patch"
+}
+
+src_configure() {
+	econf \
+		--enable-fuse \
+		--enable-library \
+		--enable-shared \
+		--with-system-zlib \
+		--with-system-bzlib \
+		$(use_enable static-libs static) \
+		$(use_with lzma xz)
+}
+
+src_install() {
+	default
+
+	# remove cruft
+	rm "${D}"/usr/bin/{davpass,ftppass} || die "rm failed"
+
+	# install docs
+	dodoc doc/{api-overview,background,FORMAT,INSTALL.*,README.avfs-fuse}
+	dosym /usr/lib/avfs/extfs/README /usr/share/doc/${PF}/README.extfs
+
+	docinto scripts
+	dodoc scripts/{avfscoda*,*pass}
+
+	use static-libs || find "${ED}" -name '*.la' -exec rm -f {} +
+}
+
+pkg_postinst() {
+	einfo "This version of AVFS includes FUSE support. It is user-based."
+	einfo "To execute:"
+	einfo "1) as user, mkdir ~/.avfs"
+	einfo "2) make sure fuse is either compiled into the kernel OR"
+	einfo "   modprobe fuse or add to startup."
+	einfo "3) run mountavfs"
+	einfo "To unload daemon, type umountavfs"
+	echo
+	einfo "READ the documentation! Enjoy :)"
+}

sdk_container/src/third_party/portage-stable/sys-fs/avfs/files/avfs-0.9.8-gcc43_fix_open_missing_mode.patch

@@ -0,0 +1,11 @@
+--- ../avfs-0.9.8_orig/modules/urar.c	2007-05-14 20:21:23.000000000 +0200
++++ modules/urar.c	2009-02-09 13:48:56.780225932 +0100
+@@ -587,7 +587,7 @@
+     if(res < 0)
+         return res;
+ 
+-    fd = open(tmpfile, O_RDWR | O_CREAT | O_TRUNC);
++    fd = open(tmpfile, O_RDWR | O_CREAT | O_TRUNC, 0644);
+     if(fd == -1) {
+         res = -errno; 
+         av_log(AVLOG_ERROR, "RAR: Could not open %s: %s", tmpfile,

sdk_container/src/third_party/portage-stable/virtual/yacc/yacc-0.ebuild

@@ -0,0 +1,15 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/virtual/yacc/yacc-0.ebuild,v 1.2 2011/08/15 13:04:46 nirbheek Exp $
+
+DESCRIPTION="virtual for yacc (yet another compiler compiler)"
+HOMEPAGE=""
+SRC_URI=""
+
+LICENSE=""
+SLOT="0"
+KEYWORDS="alpha amd64 arm hppa ia64 m68k ~mips ppc ppc64 s390 sh sparc x86 ~sparc-fbsd ~x86-fbsd"
+IUSE=""
+
+DEPEND="|| ( sys-devel/bison dev-util/yacc )"
+RDEPEND="${DEPEND}"