dev-python/setuptools: Sync with Gentoo

It's from Gentoo commit 120f357239899502e969549bdbcae87b554bc84f.

sdk_container/src/third_party/portage-stable/dev-python/setuptools/Manifest

@@ -1,2 +1 @@
-DIST setuptools-69.0.2.tar.gz 2219248 BLAKE2B 8873ce1eb0a04a8f561eaa9ea8332eb37ca8646e9ed2bb2f4723df0351b01d60ab94172ea34963b0084839b713b9a47e09ee00f82ec46297c7646565e4189ee4 SHA512 1a2955c8ff5955cb028f60ca538472c3a24dbda27984ef51ab59f6969e100b183456af82bc978a02f771b952908985eb85312065849f1afc64530d6461c7c6f6
 DIST setuptools-69.0.3.tar.gz 2219609 BLAKE2B 1a5e7896c7ea82d51b0aa4794435b9899cef871f6ae43d22ae5e08c57d87b70641f3f2abfcc29956a3de515f90b112fd61d3daf793474b4cf33f8567e3a38f4a SHA512 11df934931f4b73f7e07ea5713479593c6baa134d423556b2ae7aff0f1e5bdbdee1f5b516131adb169c838231ceb0293441fbf275ef7030dabecf74122565b6d

sdk_container/src/third_party/portage-stable/dev-python/setuptools/setuptools-69.0.2-r1.ebuild

@@ -1,115 +0,0 @@
-# Copyright 1999-2023 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-# please keep this ebuild at EAPI 8 -- sys-apps/portage dep
-EAPI=8
-
-# please bump dev-python/ensurepip-setuptools along with this package!
-
-DISTUTILS_USE_PEP517=standalone
-PYTHON_TESTED=( python3_{10..12} pypy3 )
-PYTHON_COMPAT=( "${PYTHON_TESTED[@]}" )
-PYTHON_REQ_USE="xml(+)"
-
-inherit distutils-r1 pypi
-
-DESCRIPTION="Collection of extensions to Distutils"
-HOMEPAGE="
-	https://github.com/pypa/setuptools/
-	https://pypi.org/project/setuptools/
-"
-
-LICENSE="MIT"
-SLOT="0"
-KEYWORDS="~alpha amd64 arm arm64 hppa ~ia64 ~loong ~m68k ~mips ppc ppc64 ~riscv ~s390 sparc x86 ~arm64-macos ~x64-macos ~x64-solaris"
-IUSE="test"
-RESTRICT="!test? ( test )"
-
-RDEPEND="
-	>=dev-python/jaraco-text-3.7.0-r1[${PYTHON_USEDEP}]
-	>=dev-python/more-itertools-8.12.0-r1[${PYTHON_USEDEP}]
-	>=dev-python/nspektr-0.3.0[${PYTHON_USEDEP}]
-	>=dev-python/ordered-set-4.0.2-r1[${PYTHON_USEDEP}]
-	>=dev-python/packaging-21.3-r2[${PYTHON_USEDEP}]
-	>=dev-python/platformdirs-2.6.2-r1[${PYTHON_USEDEP}]
-	>=dev-python/tomli-2.0.1[${PYTHON_USEDEP}]
-	>=dev-python/wheel-0.37.1-r1[${PYTHON_USEDEP}]
-"
-BDEPEND="
-	${RDEPEND}
-	test? (
-		$(python_gen_cond_dep '
-			dev-python/build[${PYTHON_USEDEP}]
-			>=dev-python/ini2toml-0.9[${PYTHON_USEDEP}]
-			>=dev-python/filelock-3.4.0[${PYTHON_USEDEP}]
-			>=dev-python/jaraco-envs-2.2[${PYTHON_USEDEP}]
-			>=dev-python/jaraco-path-3.2.0[${PYTHON_USEDEP}]
-			dev-python/pip[${PYTHON_USEDEP}]
-			dev-python/pip-run[${PYTHON_USEDEP}]
-			dev-python/pytest[${PYTHON_USEDEP}]
-			dev-python/pytest-fixture-config[${PYTHON_USEDEP}]
-			dev-python/pytest-timeout[${PYTHON_USEDEP}]
-			dev-python/pytest-virtualenv[${PYTHON_USEDEP}]
-			dev-python/pytest-xdist[${PYTHON_USEDEP}]
-			>=dev-python/tomli-w-1.0.0[${PYTHON_USEDEP}]
-			>=dev-python/virtualenv-20[${PYTHON_USEDEP}]
-		' "${PYTHON_TESTED[@]}")
-	)
-"
-# setuptools-scm is here because installing plugins apparently breaks stuff at
-# runtime, so let's pull it early. See bug #663324.
-PDEPEND="
-	dev-python/setuptools-scm[${PYTHON_USEDEP}]
-"
-
-src_prepare() {
-	local PATCHES=(
-		# TODO: remove this when we're 100% PEP517 mode
-		"${FILESDIR}"/setuptools-62.4.0-py-compile.patch
-	)
-
-	distutils-r1_src_prepare
-
-	# remove bundled dependencies
-	rm -r */_vendor || die
-
-	# remove the ugly */extern hack that breaks on unvendored deps
-	rm -r */extern || die
-	find -name '*.py' -exec sed \
-		-e 's:from \w*[.]\+extern ::' -e 's:\w*[.]\+extern[.]::' \
-		-i {} + || die
-}
-
-python_test() {
-	if ! has "${EPYTHON}" "${PYTHON_TESTED[@]/_/.}"; then
-		return
-	fi
-
-	local EPYTEST_DESELECT=(
-		# network
-		# TODO: see if PRE_BUILT_SETUPTOOLS_* helps
-		setuptools/tests/config/test_apply_pyprojecttoml.py::test_apply_pyproject_equivalent_to_setupcfg
-		setuptools/tests/integration/test_pip_install_sdist.py::test_install_sdist
-		setuptools/tests/test_build_meta.py::test_legacy_editable_install
-		setuptools/tests/test_distutils_adoption.py
-		setuptools/tests/test_editable_install.py
-		setuptools/tests/test_setuptools.py::test_its_own_wheel_does_not_contain_tests
-		setuptools/tests/test_virtualenv.py::test_clean_env_install
-		setuptools/tests/test_virtualenv.py::test_no_missing_dependencies
-		setuptools/tests/test_virtualenv.py::test_test_command_install_requirements
-		# TODO
-		setuptools/tests/config/test_setupcfg.py::TestConfigurationReader::test_basic
-		setuptools/tests/config/test_setupcfg.py::TestConfigurationReader::test_ignore_errors
-		setuptools/tests/test_extern.py::test_distribution_picklable
-		# expects bundled deps in virtualenv
-		setuptools/tests/config/test_apply_pyprojecttoml.py::TestMeta::test_example_file_in_sdist
-		setuptools/tests/config/test_apply_pyprojecttoml.py::TestMeta::test_example_file_not_in_wheel
-		# fails if python-xlib is installed
-		setuptools/tests/test_easy_install.py::TestSetupRequires::test_setup_requires_with_allow_hosts
-		# TODO, probably some random package
-		setuptools/tests/config/test_setupcfg.py::TestOptions::test_cmdclass
-	)
-
-	local EPYTEST_XDIST=1
-	epytest setuptools
-}

sdk_container/src/third_party/portage-stable/dev-python/setuptools/setuptools-69.0.3.ebuild

@@ -1,4 +1,4 @@
-# Copyright 1999-2023 Gentoo Authors
+# Copyright 1999-2024 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 # please keep this ebuild at EAPI 8 -- sys-apps/portage dep
@@ -21,7 +21,7 @@ HOMEPAGE="
 
 LICENSE="MIT"
 SLOT="0"
-KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~arm64-macos ~x64-macos ~x64-solaris"
+KEYWORDS="~alpha amd64 arm arm64 hppa ~ia64 ~loong ~m68k ~mips ppc ppc64 ~riscv ~s390 sparc x86 ~arm64-macos ~x64-macos ~x64-solaris"
 IUSE="test"
 RESTRICT="!test? ( test )"
 
@@ -47,9 +47,7 @@ BDEPEND="
 			dev-python/pip[${PYTHON_USEDEP}]
 			dev-python/pip-run[${PYTHON_USEDEP}]
 			dev-python/pytest[${PYTHON_USEDEP}]
-			dev-python/pytest-fixture-config[${PYTHON_USEDEP}]
 			dev-python/pytest-timeout[${PYTHON_USEDEP}]
-			dev-python/pytest-virtualenv[${PYTHON_USEDEP}]
 			dev-python/pytest-xdist[${PYTHON_USEDEP}]
 			>=dev-python/tomli-w-1.0.0[${PYTHON_USEDEP}]
 			>=dev-python/virtualenv-20[${PYTHON_USEDEP}]
@@ -111,5 +109,5 @@ python_test() {
 	)
 
 	local EPYTEST_XDIST=1
-	epytest setuptools
+	epytest -o tmp_path_retention_policy=all setuptools
 }