linux-headers: update to 3.1

BUG=chromium-os:14334
TEST=`cbuildbot chromiumos-sdk` worked
TEST=`cbuildbot amd64-generic-full` passes
TEST=`cbuildbot arm-generic-full` passes
TEST=`cbuildbot x86-generic-full` passes
TEST=build_packages+build_image for x86-alex boots

Change-Id: Ida124d9449f67c78adf9922cb81a78f20192f2f7
Reviewed-on: https://gerrit.chromium.org/gerrit/13082
Reviewed-by: Jon Kliegman <kliegs@chromium.org>
Reviewed-by: David James <davidjames@chromium.org>
Reviewed-by: Olof Johansson <olofj@chromium.org>
Commit-Ready: Mike Frysinger <vapier@chromium.org>
Tested-by: Mike Frysinger <vapier@chromium.org>

sdk_container/src/third_party/portage-stable/sys-kernel/linux-headers/linux-headers-3.1.ebuild

@@ -0,0 +1,53 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/sys-kernel/linux-headers/linux-headers-3.1.ebuild,v 1.1 2011/12/10 08:00:58 vapier Exp $
+
+EAPI="3"
+
+ETYPE="headers"
+H_SUPPORTEDARCH="alpha amd64 arm bfin cris hppa m68k mips ia64 ppc ppc64 s390 sh sparc x86"
+inherit kernel-2
+detect_version
+
+PATCH_VER="1"
+SRC_URI="mirror://gentoo/gentoo-headers-base-${PV}.tar.xz"
+[[ -n ${PATCH_VER} ]] && SRC_URI="${SRC_URI} mirror://gentoo/gentoo-headers-${PV}-${PATCH_VER}.tar.xz"
+
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-linux ~x86-linux"
+
+DEPEND="app-arch/xz-utils
+	dev-lang/perl"
+RDEPEND=""
+
+S=${WORKDIR}/gentoo-headers-base-${PV}
+
+src_unpack() {
+	unpack ${A}
+}
+
+src_prepare() {
+	has x32 $(get_all_abis) || EPATCH_EXCLUDE+=" 90_all_x32-3.1.patch"
+	[[ -n ${PATCH_VER} ]] && EPATCH_SUFFIX="patch" epatch "${WORKDIR}"/${PV}
+}
+
+src_install() {
+	kernel-2_src_install
+	cd "${D}"
+	egrep -r \
+		-e '(^|[[:space:](])(asm|volatile|inline)[[:space:](]' \
+		-e '\<([us](8|16|32|64))\>' \
+		.
+	headers___fix $(find -type f)
+
+	egrep -l -r -e '__[us](8|16|32|64)' "${D}" | xargs grep -L linux/types.h
+
+	# hrm, build system sucks
+	find "${D}" '(' -name '.install' -o -name '*.cmd' ')' -print0 | xargs -0 rm -f
+
+	# provided by libdrm (for now?)
+	rm -rf "${D}"/$(kernel_header_destdir)/drm
+}
+
+src_test() {
+	emake ARCH=$(tc-arch-kernel) headers_check || die
+}