From 5dd5ade6a45abcdbcfde89612908edf6aa572e53 Mon Sep 17 00:00:00 2001
From: Flatcar Buildbot <buildbot@flatcar-linux.org>
Date: Mon, 2 Sep 2024 07:13:40 +0000
Subject: [PATCH] dev-libs/jsoncpp: Sync with Gentoo

It's from Gentoo commit 6a1922240707d1d6538e61961efade41de887054.
---
 .../dev-libs/jsoncpp/jsoncpp-1.9.5-r1.ebuild  | 51 +++++++++++++++++++
 1 file changed, 51 insertions(+)
 create mode 100644 sdk_container/src/third_party/portage-stable/dev-libs/jsoncpp/jsoncpp-1.9.5-r1.ebuild

diff --git a/sdk_container/src/third_party/portage-stable/dev-libs/jsoncpp/jsoncpp-1.9.5-r1.ebuild b/sdk_container/src/third_party/portage-stable/dev-libs/jsoncpp/jsoncpp-1.9.5-r1.ebuild
new file mode 100644
index 0000000000..9bcbf81653
--- /dev/null
+++ b/sdk_container/src/third_party/portage-stable/dev-libs/jsoncpp/jsoncpp-1.9.5-r1.ebuild
@@ -0,0 +1,51 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..13} )
+
+inherit meson-multilib python-any-r1
+
+DESCRIPTION="C++ JSON reader and writer"
+HOMEPAGE="https://github.com/open-source-parsers/jsoncpp/"
+SRC_URI="
+	https://github.com/open-source-parsers/${PN}/archive/${PV}.tar.gz
+		-> ${P}.tar.gz
+"
+
+LICENSE="|| ( public-domain MIT )"
+SLOT="0/25"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~arm64-macos ~ppc-macos ~x64-macos ~x64-solaris"
+IUSE="doc test"
+RESTRICT="!test? ( test )"
+
+BDEPEND="
+	${PYTHON_DEPS}
+	doc? ( app-text/doxygen )
+"
+
+multilib_src_configure() {
+	local emesonargs=(
+		# Follow Debian, Ubuntu, Arch convention for headers location
+		# bug #452234
+		--includedir include/jsoncpp
+		-Dtests=$(usex test true false)
+	)
+	meson_src_configure
+}
+
+src_compile() {
+	meson-multilib_src_compile
+
+	if use doc; then
+		echo "${PV}" > version || die
+		"${EPYTHON}" doxybuild.py --doxygen="${EPREFIX}"/usr/bin/doxygen || die
+		HTML_DOCS=( dist/doxygen/jsoncpp*/. )
+	fi
+}
+
+multilib_src_test() {
+	# increase test timeout due to failures on slower hardware
+	meson_src_test -t 2
+}