dev-python/lxml: Sync with Gentoo

It's from Gentoo commit 7a9a87fec682309ff77f3383bccc348964a84ad7.

sdk_container/src/third_party/portage-stable/dev-python/lxml/Manifest

@@ -1,2 +1 @@
-DIST lxml-5.3.0.gh.tar.gz 951199 BLAKE2B 8317179c524856593b323f665c288ddddd8af7e716e1ddf1222a857c8466cfc62a6c20b21744ca418f809a3c8492216c5c9c38cfa62f2e7d51daea7343b6810b SHA512 514477bf4c865541233d73f20de816b51d265dbd75c56a0d13779e14527c73e85ca890718d06c08728da228d410459016e9cb8abdad4d03b44a81a04a198fb54
 DIST lxml-5.3.1.gh.tar.gz 951340 BLAKE2B e73cc8513cfe42d163b8475788472f00f2f3492deb7536b6556ed4f14924ffe57497947e660a161ec5a0821135b3d103799c0da0b9c647ccdcbfa9b0c5d6a1d9 SHA512 e89ada765791b67e4e83a9151c500f2e8d924c05d421a46bece1183666fc566d545d2e6b62987075e82cbafb8cd4b1f48f6f94e9ebcc0bbd7227d687b2282794

sdk_container/src/third_party/portage-stable/dev-python/lxml/lxml-5.3.0.ebuild

@@ -1,119 +0,0 @@
-# Copyright 1999-2024 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-DISTUTILS_EXT=1
-DISTUTILS_USE_PEP517=setuptools
-PYTHON_COMPAT=( python3_{10..13} pypy3 )
-
-inherit distutils-r1 optfeature toolchain-funcs
-
-DESCRIPTION="A Pythonic binding for the libxml2 and libxslt libraries"
-HOMEPAGE="
-	https://lxml.de/
-	https://pypi.org/project/lxml/
-	https://github.com/lxml/lxml/
-"
-SRC_URI="
-	https://github.com/lxml/lxml/archive/${P}.tar.gz
-		-> ${P}.gh.tar.gz
-"
-S=${WORKDIR}/lxml-${P}
-
-LICENSE="BSD ElementTree GPL-2 PSF-2"
-SLOT="0"
-KEYWORDS="~alpha amd64 arm arm64 hppa ~loong ~m68k ~mips ppc ppc64 ~riscv ~s390 sparc x86 ~amd64-linux ~x86-linux ~arm64-macos ~ppc-macos ~x64-macos ~x64-solaris"
-IUSE="doc examples +threads test"
-RESTRICT="!test? ( test )"
-
-# Note: lib{xml2,xslt} are used as C libraries, not Python modules.
-DEPEND="
-	>=dev-libs/libxml2-2.10.3
-	>=dev-libs/libxslt-1.1.38
-"
-RDEPEND="
-	${DEPEND}
-"
-BDEPEND="
-	virtual/pkgconfig
-	>=dev-python/cython-3.0.10[${PYTHON_USEDEP}]
-	doc? (
-		$(python_gen_any_dep '
-			dev-python/docutils[${PYTHON_USEDEP}]
-			dev-python/pygments[${PYTHON_USEDEP}]
-			dev-python/sphinx[${PYTHON_USEDEP}]
-			dev-python/sphinx-rtd-theme[${PYTHON_USEDEP}]
-		')
-	)
-	test? (
-		dev-python/cssselect[${PYTHON_USEDEP}]
-	)
-"
-
-PATCHES=(
-	"${FILESDIR}/${PN}-5.3.0-pypy.patch"
-)
-
-python_check_deps() {
-	use doc || return 0
-	python_has_version -b "dev-python/docutils[${PYTHON_USEDEP}]" &&
-	python_has_version -b "dev-python/pygments[${PYTHON_USEDEP}]" &&
-	python_has_version -b "dev-python/sphinx[${PYTHON_USEDEP}]" &&
-	python_has_version -b "dev-python/sphinx-rtd-theme[${PYTHON_USEDEP}]"
-}
-
-python_prepare_all() {
-	# don't use some random SDK on Darwin
-	sed -i -e '/_ldflags =/s/=.*isysroot.*darwin.*None/= None/' \
-		setupinfo.py || die
-
-	distutils-r1_python_prepare_all
-}
-
-python_compile() {
-	local DISTUTILS_ARGS=(
-		# by default it adds -w to CFLAGS
-		--warnings
-	)
-	tc-export PKG_CONFIG
-	distutils-r1_python_compile
-}
-
-python_compile_all() {
-	use doc && emake html
-}
-
-python_test() {
-	local dir=${BUILD_DIR}/test$(python_get_sitedir)/lxml
-	local -x PATH=${BUILD_DIR}/test/usr/bin:${PATH}
-
-	cp -al "${BUILD_DIR}"/{install,test} || die
-	cp -al src/lxml/tests "${dir}/" || die
-	cp -al src/lxml/html/tests "${dir}/html/" || die
-	mkdir "${dir}"/../../doc || die
-	# this one needs to be copied, because upstream uses doc/../../../doc
-	cp -r "${S}"/doc "${dir}"/../../ || die
-	ln -s "${S}"/doc "${dir}"/../../../../ || die
-
-	"${EPYTHON}" test.py --no-src -vv --all-levels -p ||
-		die "Tests fail on ${EPYTHON}"
-}
-
-python_install_all() {
-	if use doc; then
-		local DOCS=( README.rst *.txt doc/*.txt )
-		local HTML_DOCS=( doc/html/. )
-	fi
-	if use examples; then
-		dodoc -r samples
-	fi
-
-	distutils-r1_python_install_all
-}
-
-pkg_postinst() {
-	optfeature "Support for BeautifulSoup as a parser backend" dev-python/beautifulsoup4
-	optfeature "Translates CSS selectors to XPath 1.0 expressions" dev-python/cssselect
-	optfeature "Support for lxml.html.clean sanitizer" dev-python/lxml-html-clean
-}

sdk_container/src/third_party/portage-stable/dev-python/lxml/lxml-5.3.1.ebuild

@@ -23,7 +23,7 @@ S=${WORKDIR}/lxml-${P}
 
 LICENSE="BSD ElementTree GPL-2 PSF-2"
 SLOT="0"
-KEYWORDS="~alpha amd64 arm arm64 ~hppa ~loong ~m68k ~mips ppc ppc64 ~riscv ~s390 sparc x86 ~amd64-linux ~x86-linux ~arm64-macos ~ppc-macos ~x64-macos ~x64-solaris"
+KEYWORDS="~alpha amd64 arm arm64 hppa ~loong ~m68k ~mips ppc ppc64 ~riscv ~s390 sparc x86 ~amd64-linux ~x86-linux ~arm64-macos ~ppc-macos ~x64-macos ~x64-solaris"
 IUSE="doc examples +threads test"
 RESTRICT="!test? ( test )"