dev-python/hatchling: Sync with Gentoo

It's from Gentoo commit 13942020efe3589f2de03d0e16cb44d24ad1d71c.

sdk_container/src/third_party/portage-stable/dev-python/hatchling/Manifest

@@ -1,2 +1,3 @@
 DIST hatch-hatchling-v1.25.0.gh.tar.gz 5276942 BLAKE2B 76de1a824086889370a996945ad031179132dc74f4ef8a79da29913fc587c85210db49e89f400f4db2533d6706452cd4c67b87ff4ca97be0c3dc1879cf2bd77e SHA512 54f4e5f9383e846a9192e47b61f5147d4c48f20c41df752898dc5e22dd0bf196ea60fe4866dd04dc09c763aac67f7c047c40d978398e910878eb772af887d607
 DIST hatch-hatchling-v1.26.1.gh.tar.gz 5276205 BLAKE2B 135dff9ee6a56d15a2a8019452b3b9b3b78bc1c7501ccd3d6b85769e12348d582f974f9337b87e24f09add877a835b7d40076e79b2a0636ea12dc3e66085eb98 SHA512 e05c0f464604119deac12b176ebe257a7c00eb550570292bb179a7a6a648fa589db59b029f2c795bd465e580fbc258f3e302d6cce8a934b708d0674a00f89458
+DIST hatch-hatchling-v1.26.3.gh.tar.gz 5275661 BLAKE2B 2aa7ac3cfb0e07b29765749fca94bdf6f54eb4fe38b809851b4a41ab7dde28faa304c2efc0f9a1cb53868167ad1c01871723cb89aa299d0619b8fa190435bb95 SHA512 1e62384acdf6707297a2847cdba2da4d63caf48d7428544c70b106d75aa3966f4204cd172cf9ddf25e5c1fe8c029c6730cf884c705ebfdc4f93773fa6527e5a4

sdk_container/src/third_party/portage-stable/dev-python/hatchling/hatchling-1.26.3.ebuild

@@ -0,0 +1,105 @@
+# Copyright 2022-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=standalone
+PYTHON_TESTED=( pypy3 python3_{10..13} )
+PYTHON_COMPAT=( "${PYTHON_TESTED[@]}" python3_13t )
+
+inherit distutils-r1
+
+TAG=${P/-/-v}
+MY_P=hatch-${TAG}
+DESCRIPTION="Modern, extensible Python build backend"
+HOMEPAGE="
+	https://pypi.org/project/hatchling/
+	https://github.com/pypa/hatch/
+"
+SRC_URI="
+	https://github.com/pypa/hatch/archive/${TAG}.tar.gz
+		-> ${MY_P}.gh.tar.gz
+"
+S=${WORKDIR}/${MY_P}/backend
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~arm64-macos ~ppc-macos ~x64-macos ~x64-solaris"
+
+# deps are listed in backend/src/hatchling/ouroboros.py
+# editables are optional but required for editable installs
+RDEPEND="
+	>=dev-python/editables-0.3[${PYTHON_USEDEP}]
+	>=dev-python/packaging-24.2[${PYTHON_USEDEP}]
+	>=dev-python/pathspec-0.10.1[${PYTHON_USEDEP}]
+	>=dev-python/pluggy-1.0.0[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep '
+		>=dev-python/tomli-1.2.2[${PYTHON_USEDEP}]
+	' 3.10)
+"
+# always depend on the newest version available, at least until upstream
+# stops treating unknown classifiers as a fatal error
+# https://github.com/pypa/hatch/issues/1368
+RDEPEND+="
+	>=dev-python/trove-classifiers-2024.10.16[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	${RDEPEND}
+	test? (
+		$(python_gen_cond_dep '
+			dev-python/atomicwrites[${PYTHON_USEDEP}]
+			dev-python/click[${PYTHON_USEDEP}]
+			dev-python/httpx[${PYTHON_USEDEP}]
+			dev-python/platformdirs[${PYTHON_USEDEP}]
+			dev-python/pytest-mock[${PYTHON_USEDEP}]
+			dev-python/rich[${PYTHON_USEDEP}]
+			dev-python/tomli-w[${PYTHON_USEDEP}]
+			dev-python/virtualenv[${PYTHON_USEDEP}]
+		' "${PYTHON_TESTED[@]}")
+	)
+"
+
+distutils_enable_tests pytest
+
+src_test() {
+	# top-level "tests" directory contains tests both for hatch
+	# and hatchling
+	cd "${WORKDIR}/${MY_P}" || die
+
+	# sigh; standalone test suites are overrated, right?
+	echo "__version__ = '${PV}'" > src/hatch/_version.py || die
+	local -x PYTHONPATH="src:${PYTHONPATH}"
+
+	# do not require uv for portability, sigh
+	mkdir "${T}/bin" || die
+	cat > "${T}/bin/uv" <<-EOF || die
+		#!/bin/sh
+		exit 127
+	EOF
+	chmod +x "${T}/bin/uv" || die
+	local -x PATH=${T}/bin:${PATH}
+
+	# tests mock cargo subprocess call but the backend raises if CARGO
+	# is not set and shutil.which() can't find it
+	local -x CARGO=cargo
+
+	distutils-r1_src_test
+}
+
+python_test() {
+	if ! has "${EPYTHON}" "${PYTHON_TESTED[@]/_/.}"; then
+		einfo "Skipping tests on ${EPYTHON}"
+		return
+	fi
+
+	local -x EPYTEST_DESELECT=(
+		# most of these run uv to install stuff
+		# the few remaining tests aren't worth running
+		tests/backend/dep/test_core.py
+		# broken if CARGO is set
+		tests/backend/builders/test_binary.py::TestBuildBootstrap::test_no_cargo
+	)
+
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	epytest -p pytest_mock tests/backend
+}