From 32ae0350be3f1d86301ee6fa6fb701a9f9d9fc66 Mon Sep 17 00:00:00 2001
From: Flatcar Buildbot <buildbot@flatcar-linux.org>
Date: Mon, 21 Oct 2024 07:05:14 +0000
Subject: [PATCH] dev-libs/jsoncpp: Sync with Gentoo

It's from Gentoo commit 6400da7d28c2fa539c6d756a89a308a2720c813d.
---
 .../dev-libs/jsoncpp/jsoncpp-1.9.6-r2.ebuild  | 57 +++++++++++++++++++
 .../dev-libs/jsoncpp/jsoncpp-1.9.6.ebuild     |  2 +-
 2 files changed, 58 insertions(+), 1 deletion(-)
 create mode 100644 sdk_container/src/third_party/portage-stable/dev-libs/jsoncpp/jsoncpp-1.9.6-r2.ebuild

diff --git a/sdk_container/src/third_party/portage-stable/dev-libs/jsoncpp/jsoncpp-1.9.6-r2.ebuild b/sdk_container/src/third_party/portage-stable/dev-libs/jsoncpp/jsoncpp-1.9.6-r2.ebuild
new file mode 100644
index 0000000000..6f037fec5a
--- /dev/null
+++ b/sdk_container/src/third_party/portage-stable/dev-libs/jsoncpp/jsoncpp-1.9.6-r2.ebuild
@@ -0,0 +1,57 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..13} )
+
+inherit meson-multilib python-any-r1
+
+DESCRIPTION="C++ JSON reader and writer"
+HOMEPAGE="https://github.com/open-source-parsers/jsoncpp/"
+SRC_URI="
+	https://github.com/open-source-parsers/${PN}/archive/${PV}.tar.gz
+		-> ${P}.tar.gz
+"
+
+LICENSE="|| ( public-domain MIT )"
+SLOT="0/26"
+KEYWORDS="~alpha amd64 ~arm ~arm64 ~hppa ~loong ~m68k ~mips ppc ppc64 ~riscv ~s390 sparc x86 ~amd64-linux ~arm64-macos ~ppc-macos ~x64-macos ~x64-solaris"
+IUSE="doc test"
+RESTRICT="!test? ( test )"
+
+BDEPEND="
+	${PYTHON_DEPS}
+	doc? ( app-text/doxygen )
+"
+
+multilib_src_configure() {
+	local emesonargs=(
+		# Follow Debian, Ubuntu, Arch convention for headers location
+		# bug #452234
+		--includedir include/jsoncpp
+		-Dtests=$(usex test true false)
+	)
+	meson_src_configure
+}
+
+src_compile() {
+	meson-multilib_src_compile
+
+	if use doc; then
+		echo "${PV}" > version || die
+		"${EPYTHON}" doxybuild.py --doxygen="${EPREFIX}"/usr/bin/doxygen || die
+		HTML_DOCS=( dist/doxygen/jsoncpp*/. )
+	fi
+}
+
+multilib_src_test() {
+	# increase test timeout due to failures on slower hardware
+	meson_src_test -t 2
+}
+
+multilib_src_install() {
+	meson_install
+	# https://bugs.gentoo.org/941642
+	rm -r "${ED}/usr/$(get_libdir)/cmake" || die
+}
diff --git a/sdk_container/src/third_party/portage-stable/dev-libs/jsoncpp/jsoncpp-1.9.6.ebuild b/sdk_container/src/third_party/portage-stable/dev-libs/jsoncpp/jsoncpp-1.9.6.ebuild
index 92c06cb15f..b38818f791 100644
--- a/sdk_container/src/third_party/portage-stable/dev-libs/jsoncpp/jsoncpp-1.9.6.ebuild
+++ b/sdk_container/src/third_party/portage-stable/dev-libs/jsoncpp/jsoncpp-1.9.6.ebuild
@@ -16,7 +16,7 @@ SRC_URI="
 
 LICENSE="|| ( public-domain MIT )"
 SLOT="0/26"
-KEYWORDS="~alpha amd64 arm arm64 ~hppa ~loong ~m68k ~mips ppc ppc64 ~riscv ~s390 ~sparc x86 ~amd64-linux ~arm64-macos ~ppc-macos ~x64-macos ~x64-solaris"
+KEYWORDS="~alpha amd64 arm arm64 ~hppa ~loong ~m68k ~mips ppc ppc64 ~riscv ~s390 sparc x86 ~amd64-linux ~arm64-macos ~ppc-macos ~x64-macos ~x64-solaris"
 IUSE="doc test"
 RESTRICT="!test? ( test )"