dev-python/jinja: Add new package for systemd dependency

Signed-off-by: Sayan Chowdhury <schowdhury@microsoft.com>
This commit is contained in:
Sayan Chowdhury 2021-09-29 21:06:39 +00:00 committed by Sayan Chowdhury
parent 46b66f6236
commit 1c6a2d831e
3 changed files with 83 additions and 0 deletions

View File

@ -0,0 +1 @@
DIST jinja-2.11.2.tar.gz 258055 BLAKE2B 5cf12d6c79e7e659b16318cb3dc483a276511192903469629ec497c10ba6cd023f5a834961ac74cbda556177aaac46f5045c5aaca3068dcef87017760895851c SHA512 453e0c94c57065ab78f997726256bd2a31bb79124a2ee17b632cb124a3ccefded33d81b35cac73497f095b1cd5d8cd4420d6932a637fd7c4cdb786f1753e49ac

View File

@ -0,0 +1,68 @@
# Copyright 1999-2021 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
DISTUTILS_USE_SETUPTOOLS=rdepend
PYTHON_COMPAT=( python3_{6,7,8,9} pypy3 )
PYTHON_REQ_USE="threads(+)"
inherit distutils-r1
DESCRIPTION="A full-featured template engine for Python"
HOMEPAGE="https://jinja.palletsprojects.com/ https://pypi.org/project/Jinja2/"
# pypi tarball is missing tests
SRC_URI="https://github.com/pallets/jinja/archive/${PV}.tar.gz -> ${P}.tar.gz"
LICENSE="BSD"
SLOT="0"
KEYWORDS="~alpha amd64 arm arm64 hppa ~ia64 ~mips ppc ppc64 ~riscv s390 sparc x86 ~amd64-linux ~x86-linux ~x64-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris"
IUSE="examples"
RDEPEND="
dev-python/markupsafe[${PYTHON_USEDEP}]
!dev-python/jinja:compat"
distutils_enable_sphinx docs \
dev-python/sphinx-issues \
dev-python/pallets-sphinx-themes
distutils_enable_tests pytest
# XXX: handle Babel better?
src_prepare() {
# avoid unnecessary dep on extra sphinxcontrib modules
sed -i '/sphinxcontrib.log_cabinet/ d' docs/conf.py || die
distutils-r1_src_prepare
}
python_compile() {
distutils-r1_python_compile
if ! python_is_python3; then
rm "${BUILD_DIR}"/lib/jinja2/async*.py || die
fi
}
python_install() {
distutils-r1_python_install --skip-build
}
python_install_all() {
if use examples ; then
docinto examples
dodoc -r examples/.
fi
distutils-r1_python_install_all
insinto /usr/share/vim/vimfiles/syntax
doins ext/Vim/*
}
pkg_postinst() {
if ! has_version dev-python/Babel; then
elog "For i18n support, please emerge dev-python/Babel."
fi
}

View File

@ -0,0 +1,14 @@
<?xml version='1.0' encoding='UTF-8'?>
<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
<pkgmetadata>
<maintainer type="project">
<email>python@gentoo.org</email>
<name>Python</name>
</maintainer>
<stabilize-allarches/>
<upstream>
<remote-id type="pypi">Jinja2</remote-id>
<remote-id type="github">pallets/jinja</remote-id>
<remote-id type="cpe">cpe:/a:palletsprojects:jinja</remote-id>
</upstream>
</pkgmetadata>