mirror of
https://github.com/flatcar/scripts.git
synced 2025-09-24 15:11:19 +02:00
net-libs/gnutls: Sync with Gentoo
It's from Gentoo commit 33d65fae66a6e7767baf7ec163834b8e7d6afd46.
This commit is contained in:
Flatcar Buildbot
Krzesimir Nowak
parent
647e9c39d0
commit
0c5b33e56a
@ -8,3 +8,5 @@ DIST gnutls-3.7.9.tar.xz 6377212 BLAKE2B c8263381132b0c96f23a580823cfaf571120568
|
||||
DIST gnutls-3.7.9.tar.xz.sig 685 BLAKE2B 2e7ba793d026cf96c54c75a81160c58cf21d6d5f034a603ffe88d5fa4cbfa1d4fd590efbe81fbee7790cd4956776085b7827fead67c9b07f1d7eadd405815eb7 SHA512 906227a0d6f57878e85e9acdf754d20b7628a7a95b40aeffced398a0a0c6220f5e32191a9f988f55b8b903bf55212179dce2abcc08c2bb3397a2704dd2319438
|
||||
DIST gnutls-3.8.0.tar.xz 6378480 BLAKE2B 64784e9c0ac4dcab2c9e90d7d17d0bd8a0021224be285c12a53673f3a52aa3f189152b1b0b4aaae5a8fb41951361af1fd04a5b535774c4a26c26eb895519af40 SHA512 2507b3133423fdaf90fbd826ccb1142e9ff6fc90fcd5531720218f19ddf0e6bbb8267d23bad35c0954860e5a4179da74823e0c8357db56a14f252e6ec9d59629
|
||||
DIST gnutls-3.8.0.tar.xz.sig 684 BLAKE2B c5dbed12b8233ed8502dac16b77d6043591296f4b9ddb0445271e8fe875c2a05b9663ad6523cca6355faaa9d244cc6e6fb8ff0d65fee47b36ab6b57f57d89f64 SHA512 9db8db74aa0ebd871287b07b6a8a9f4ce90188633618e669fe07cb8bb314b624c14761f6fe1970e2fbffa87f7c0d6daa4b0fa838bd05f74b8b18cd1b5325c654
|
||||
DIST gnutls-3.8.1.tar.xz 6447056 BLAKE2B 16cb6d2dc7d67724ff45765ae3f154c8d268d8c4547df591a95ff014fc18f16f572a76e3cd00b3e13615ba41e80141cef21aa9915b467a1c452edfe314e2e0c7 SHA512 22e78db86b835843df897d14ad633d8a553c0f9b1389daa0c2f864869c6b9ca889028d434f9552237dc4f1b37c978fbe0cce166e3768e5d4e8850ff69a6fc872
|
||||
DIST gnutls-3.8.1.tar.xz.sig 685 BLAKE2B bfafa80bef81c2a24556f010f00294643ba7901eff07f055a0ebd9ca532b47b7b3d3403e9d1a1389c14e6f37f474a37afa2844f326d5ab35fa35b195f2ff1ade SHA512 f03fde611927c83f6b57af695d5610ba3cefbb88a261cf5485c94b3fb32c7480a77c68a353a6a28185337195e30011d6b5578c53ea4180a656cf7b175156f7f1
|
||||
|
||||
@ -17,7 +17,7 @@ LICENSE="GPL-3 LGPL-2.1+"
|
||||
# Subslot format:
|
||||
# <libgnutls.so number>.<libgnutlsxx.so number>
|
||||
SLOT="0/30.30"
|
||||
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~arm64-macos ~ppc-macos ~x64-macos ~x64-solaris"
|
||||
KEYWORDS="~alpha amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ppc ppc64 ~riscv ~s390 sparc x86 ~amd64-linux ~x86-linux ~arm64-macos ~ppc-macos ~x64-macos ~x64-solaris"
|
||||
IUSE="brotli +cxx dane doc examples +idn nls +openssl pkcs11 seccomp sslv2 sslv3 static-libs test test-full +tls-heartbeat tools zlib zstd"
|
||||
REQUIRED_USE="test-full? ( cxx dane doc examples idn nls openssl pkcs11 seccomp tls-heartbeat tools )"
|
||||
RESTRICT="!test? ( test )"
|
||||
|
||||
142
sdk_container/src/third_party/portage-stable/net-libs/gnutls/gnutls-3.8.1.ebuild
vendored
Normal file
142
sdk_container/src/third_party/portage-stable/net-libs/gnutls/gnutls-3.8.1.ebuild
vendored
Normal file
@ -0,0 +1,142 @@
|
||||
# Copyright 1999-2023 Gentoo Authors
|
||||
# Distributed under the terms of the GNU General Public License v2
|
||||
|
||||
EAPI=8
|
||||
|
||||
VERIFY_SIG_OPENPGP_KEY_PATH="${BROOT}"/usr/share/openpgp-keys/gnutls.asc
|
||||
inherit libtool multilib-minimal verify-sig
|
||||
|
||||
DESCRIPTION="A secure communications library implementing the SSL, TLS and DTLS protocols"
|
||||
HOMEPAGE="https://www.gnutls.org/"
|
||||
SRC_URI="mirror://gnupg/gnutls/v$(ver_cut 1-2)/${P}.tar.xz"
|
||||
SRC_URI+=" verify-sig? ( mirror://gnupg/gnutls/v$(ver_cut 1-2)/${P}.tar.xz.sig )"
|
||||
|
||||
LICENSE="GPL-3 LGPL-2.1+"
|
||||
# As of 3.8.0, the C++ library is header-only, but we won't drop the subslot
|
||||
# component for it until libgnutls.so breaks ABI, to avoid pointless rebuilds.
|
||||
# Subslot format:
|
||||
# <libgnutls.so number>.<libgnutlsxx.so number>
|
||||
SLOT="0/30.30"
|
||||
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~arm64-macos ~ppc-macos ~x64-macos ~x64-solaris"
|
||||
IUSE="brotli +cxx dane doc examples +idn nls +openssl pkcs11 seccomp sslv2 sslv3 static-libs test test-full +tls-heartbeat tools zlib zstd"
|
||||
REQUIRED_USE="test-full? ( cxx dane doc examples idn nls openssl pkcs11 seccomp tls-heartbeat tools )"
|
||||
RESTRICT="!test? ( test )"
|
||||
|
||||
RDEPEND="
|
||||
>=dev-libs/libtasn1-4.9:=[${MULTILIB_USEDEP}]
|
||||
dev-libs/libunistring:=[${MULTILIB_USEDEP}]
|
||||
>=dev-libs/nettle-3.6:=[gmp,${MULTILIB_USEDEP}]
|
||||
>=dev-libs/gmp-5.1.3-r1:=[${MULTILIB_USEDEP}]
|
||||
brotli? ( >=app-arch/brotli-1.0.0:=[${MULTILIB_USEDEP}] )
|
||||
dane? ( >=net-dns/unbound-1.4.20:=[${MULTILIB_USEDEP}] )
|
||||
nls? ( >=virtual/libintl-0-r1:=[${MULTILIB_USEDEP}] )
|
||||
pkcs11? ( >=app-crypt/p11-kit-0.23.1[${MULTILIB_USEDEP}] )
|
||||
idn? ( >=net-dns/libidn2-0.16-r1:=[${MULTILIB_USEDEP}] )
|
||||
zlib? ( sys-libs/zlib[${MULTILIB_USEDEP}] )
|
||||
zstd? ( >=app-arch/zstd-1.3.0:=[${MULTILIB_USEDEP}] )
|
||||
"
|
||||
DEPEND="
|
||||
${RDEPEND}
|
||||
test? (
|
||||
seccomp? ( sys-libs/libseccomp )
|
||||
)
|
||||
"
|
||||
BDEPEND="
|
||||
dev-util/gtk-doc-am
|
||||
>=virtual/pkgconfig-0-r1
|
||||
doc? ( dev-util/gtk-doc )
|
||||
nls? ( sys-devel/gettext )
|
||||
test-full? (
|
||||
app-crypt/dieharder
|
||||
|| ( sys-libs/libfaketime >=app-misc/datefudge-1.22 )
|
||||
dev-libs/softhsm:2[-bindist(-)]
|
||||
net-dialup/ppp
|
||||
net-misc/socat
|
||||
)
|
||||
verify-sig? ( >=sec-keys/openpgp-keys-gnutls-20221017 )
|
||||
"
|
||||
|
||||
DOCS=( README.md doc/certtool.cfg )
|
||||
|
||||
HTML_DOCS=()
|
||||
|
||||
src_prepare() {
|
||||
default
|
||||
|
||||
# bug #520818
|
||||
export TZ=UTC
|
||||
|
||||
use doc && HTML_DOCS+=( doc/gnutls.html )
|
||||
|
||||
# don't try to use system certificate store on macOS, it is
|
||||
# confusingly ignoring our ca-certificates and more importantly
|
||||
# fails to compile in certain configurations
|
||||
sed -i -e 's/__APPLE__/__NO_APPLE__/' lib/system/certs.c || die
|
||||
|
||||
# Use sane .so versioning on FreeBSD.
|
||||
elibtoolize
|
||||
}
|
||||
|
||||
multilib_src_configure() {
|
||||
LINGUAS="${LINGUAS//en/en@boldquot en@quot}"
|
||||
|
||||
local libconf=()
|
||||
|
||||
# TPM needs to be tested before being enabled
|
||||
# Note that this may add a libltdl dep when enabled. Check configure.ac.
|
||||
libconf+=(
|
||||
--without-tpm
|
||||
--without-tpm2
|
||||
)
|
||||
|
||||
# hardware-accel is disabled on OSX because the asm files force
|
||||
# GNU-stack (as doesn't support that) and when that's removed ld
|
||||
# complains about duplicate symbols
|
||||
[[ ${CHOST} == *-darwin* ]] && libconf+=( --disable-hardware-acceleration )
|
||||
|
||||
# -fanalyzer substantially slows down the build and isn't useful for
|
||||
# us. It's useful for upstream as it's static analysis, but it's not
|
||||
# useful when just getting something built.
|
||||
export gl_cv_warn_c__fanalyzer=no
|
||||
|
||||
local myeconfargs=(
|
||||
--disable-valgrind-tests
|
||||
$(multilib_native_enable manpages)
|
||||
$(multilib_native_use_enable doc gtk-doc)
|
||||
$(multilib_native_use_enable doc)
|
||||
$(multilib_native_use_enable seccomp seccomp-tests)
|
||||
$(multilib_native_use_enable test tests)
|
||||
$(multilib_native_use_enable test-full full-test-suite)
|
||||
$(multilib_native_use_enable tools)
|
||||
$(use_enable cxx)
|
||||
$(use_enable dane libdane)
|
||||
$(use_enable nls)
|
||||
$(use_enable openssl openssl-compatibility)
|
||||
$(use_enable sslv2 ssl2-support)
|
||||
$(use_enable sslv3 ssl3-support)
|
||||
$(use_enable static-libs static)
|
||||
$(use_enable tls-heartbeat heartbeat-support)
|
||||
$(use_with brotli)
|
||||
$(use_with idn)
|
||||
$(use_with pkcs11 p11-kit)
|
||||
$(use_with zlib)
|
||||
$(use_with zstd)
|
||||
--disable-rpath
|
||||
--with-default-trust-store-file="${EPREFIX}"/etc/ssl/certs/ca-certificates.crt
|
||||
--with-unbound-root-key-file="${EPREFIX}"/etc/dnssec/root-anchors.txt
|
||||
--without-included-libtasn1
|
||||
$("${S}/configure" --help | grep -o -- '--without-.*-prefix')
|
||||
)
|
||||
|
||||
ECONF_SOURCE="${S}" econf "${libconf[@]}" "${myeconfargs[@]}"
|
||||
}
|
||||
|
||||
multilib_src_install_all() {
|
||||
einstalldocs
|
||||
find "${ED}" -type f -name '*.la' -delete || die
|
||||
|
||||
if use examples; then
|
||||
docinto examples
|
||||
dodoc doc/examples/*.c
|
||||
fi
|
||||
}
|
||||
Loading…
x
Reference in New Issue
Block a user