dev-util/catalyst: Sync with Gentoo

It's from Gentoo commit 8cb5483f0ef5ea115748f8db5545a77aca4fcdcf.

sdk_container/src/third_party/portage-stable/dev-util/catalyst/catalyst-3.0.22-r3.ebuild

@@ -0,0 +1,82 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+if [[ ${PV} == *9999* ]]; then
+	SRC_ECLASS="git-r3"
+	EGIT_REPO_URI="https://anongit.gentoo.org/git/proj/catalyst.git"
+	EGIT_BRANCH="master"
+else
+	SRC_URI="https://gitweb.gentoo.org/proj/catalyst.git/snapshot/${P}.tar.bz2"
+	KEYWORDS="~alpha amd64 arm arm64 ~hppa ~ia64 ~mips ppc ppc64 ~riscv ~s390 sparc x86"
+fi
+
+PYTHON_COMPAT=( python3_{9..11} )
+DISTUTILS_USE_PEP517=setuptools
+
+inherit distutils-r1 ${SRC_ECLASS}
+
+DESCRIPTION="Release metatool used for creating releases based on Gentoo Linux"
+HOMEPAGE="https://wiki.gentoo.org/wiki/Catalyst"
+
+LICENSE="GPL-2+"
+SLOT="0"
+IUSE="ccache doc +iso system-bootloader"
+
+DEPEND="
+	app-text/asciidoc
+	>=dev-python/snakeoil-0.6.5[${PYTHON_USEDEP}]
+	dev-python/fasteners[${PYTHON_USEDEP}]
+"
+RDEPEND="
+	>=dev-python/snakeoil-0.6.5[${PYTHON_USEDEP}]
+	dev-python/fasteners[${PYTHON_USEDEP}]
+	>=dev-python/pydecomp-0.3[${PYTHON_USEDEP}]
+	app-arch/lbzip2
+	app-crypt/shash
+	sys-fs/dosfstools
+	|| (
+		app-arch/tar[xattr]
+		app-arch/libarchive[xattr]
+	)
+	amd64? ( >=sys-boot/syslinux-3.72 )
+	x86? ( >=sys-boot/syslinux-3.72 )
+	ccache? ( dev-util/ccache )
+	iso? ( app-cdr/cdrtools )
+	kernel_linux? ( app-misc/zisofs-tools >=sys-fs/squashfs-tools-2.1 )
+"
+PDEPEND="system-bootloader? ( >=sys-apps/memtest86+-5.01-r4
+				sys-boot/grub:2
+				amd64? ( sys-boot/grub[grub_platforms_efi-32,grub_platforms_efi-64] )
+				x86? ( sys-boot/grub[grub_platforms_efi-32] )
+				sys-boot/syslinux
+				sys-boot/shim )"
+
+python_prepare_all() {
+	python_setup
+	echo VERSION="${PV}" "${PYTHON}" setup.py set_version
+	VERSION="${PV}" "${PYTHON}" setup.py set_version || die
+	distutils-r1_python_prepare_all
+}
+
+# Build man pages here so as to not clobber default src_compile
+src_configure() {
+	# build the man pages and docs
+	emake
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+	if use doc; then
+		dodoc files/HOWTO.html files/docbook-xsl.css
+	fi
+}
+
+src_install() {
+	distutils-r1_src_install
+
+	doman files/catalyst.1 files/catalyst-config.5 files/catalyst-spec.5
+	insinto /etc/catalyst
+	doins etc/*
+}

sdk_container/src/third_party/portage-stable/dev-util/catalyst/catalyst-9999.ebuild

@@ -13,7 +13,7 @@ else
 fi
 
 PYTHON_COMPAT=( python3_{9..11} )
-DISTUTILS_USE_SETUPTOOLS=no
+DISTUTILS_USE_PEP517=setuptools
 
 inherit distutils-r1 linux-info optfeature tmpfiles ${SRC_ECLASS}
 
@@ -90,7 +90,8 @@ python_prepare_all() {
 	distutils-r1_python_prepare_all
 }
 
-python_compile_all() {
+# Build man pages here so as to not clobber default src_compile
+src_configure() {
 	# build the man pages and docs
 	emake
 }
@@ -107,10 +108,15 @@ src_install() {
 
 	echo 'd /var/tmp/catalyst 0755 root root' > "${T}"/catalyst-tmpdir.conf
 	dotmpfiles "${T}"/catalyst-tmpdir.conf
+
+	doman files/catalyst.1 files/catalyst-config.5 files/catalyst-spec.5
+	insinto /etc/catalyst
+	doins etc/*
 }
 
 pkg_postinst() {
 	if [[ -z ${REPLACING_VERSIONS} ]]; then
 		optfeature "ccache support" dev-util/ccache
 	fi
+	tmpfiles_process catalyst-tmpdir.conf
 }