mirror of
https://github.com/ARM-software/arm-trusted-firmware.git
synced 2025-08-23 23:41:19 +02:00
8b779620d3
In order for the symbol table in the ELF file to contain the size of functions written in assembly, it is necessary to report it to the assembler using the .size directive. To fulfil the above requirements, this patch introduces an 'endfunc' macro which contains the .endfunc and .size directives. It also adds a .func directive to the 'func' assembler macro. The .func/.endfunc have been used so the assembler can fail if endfunc is omitted. Fixes ARM-Software/tf-issues#295 Change-Id: If8cb331b03d7f38fe7e3694d4de26f1075b278fc Signed-off-by: Kévin Petit <kevin.petit@arm.com>
220 lines
6.6 KiB
ArmAsm
220 lines
6.6 KiB
ArmAsm
/*
|
|
* Copyright (c) 2013-2014, ARM Limited and Contributors. All rights reserved.
|
|
*
|
|
* Redistribution and use in source and binary forms, with or without
|
|
* modification, are permitted provided that the following conditions are met:
|
|
*
|
|
* Redistributions of source code must retain the above copyright notice, this
|
|
* list of conditions and the following disclaimer.
|
|
*
|
|
* Redistributions in binary form must reproduce the above copyright notice,
|
|
* this list of conditions and the following disclaimer in the documentation
|
|
* and/or other materials provided with the distribution.
|
|
*
|
|
* Neither the name of ARM nor the names of its contributors may be used
|
|
* to endorse or promote products derived from this software without specific
|
|
* prior written permission.
|
|
*
|
|
* THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS "AS IS"
|
|
* AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
|
|
* IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
|
|
* ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT HOLDER OR CONTRIBUTORS BE
|
|
* LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR
|
|
* CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF
|
|
* SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS
|
|
* INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN
|
|
* CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE)
|
|
* ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
|
|
* POSSIBILITY OF SUCH DAMAGE.
|
|
*/
|
|
|
|
#include <arch.h>
|
|
#include <asm_macros.S>
|
|
|
|
.globl flush_dcache_range
|
|
.globl inv_dcache_range
|
|
.globl dcsw_op_louis
|
|
.globl dcsw_op_all
|
|
.globl dcsw_op_level1
|
|
.globl dcsw_op_level2
|
|
.globl dcsw_op_level3
|
|
|
|
/* ------------------------------------------
|
|
* Clean+Invalidate from base address till
|
|
* size. 'x0' = addr, 'x1' = size
|
|
* ------------------------------------------
|
|
*/
|
|
func flush_dcache_range
|
|
dcache_line_size x2, x3
|
|
add x1, x0, x1
|
|
sub x3, x2, #1
|
|
bic x0, x0, x3
|
|
flush_loop:
|
|
dc civac, x0
|
|
add x0, x0, x2
|
|
cmp x0, x1
|
|
b.lo flush_loop
|
|
dsb sy
|
|
ret
|
|
endfunc flush_dcache_range
|
|
|
|
|
|
/* ------------------------------------------
|
|
* Invalidate from base address till
|
|
* size. 'x0' = addr, 'x1' = size
|
|
* ------------------------------------------
|
|
*/
|
|
func inv_dcache_range
|
|
dcache_line_size x2, x3
|
|
add x1, x0, x1
|
|
sub x3, x2, #1
|
|
bic x0, x0, x3
|
|
inv_loop:
|
|
dc ivac, x0
|
|
add x0, x0, x2
|
|
cmp x0, x1
|
|
b.lo inv_loop
|
|
dsb sy
|
|
ret
|
|
endfunc inv_dcache_range
|
|
|
|
|
|
/* ---------------------------------------------------------------
|
|
* Data cache operations by set/way to the level specified
|
|
*
|
|
* The main function, do_dcsw_op requires:
|
|
* x0: The operation type (0-2), as defined in arch.h
|
|
* x3: The last cache level to operate on
|
|
* x9: clidr_el1
|
|
* x10: The cache level to begin operation from
|
|
* and will carry out the operation on each data cache from level 0
|
|
* to the level in x3 in sequence
|
|
*
|
|
* The dcsw_op macro sets up the x3 and x9 parameters based on
|
|
* clidr_el1 cache information before invoking the main function
|
|
* ---------------------------------------------------------------
|
|
*/
|
|
|
|
.macro dcsw_op shift, fw, ls
|
|
mrs x9, clidr_el1
|
|
ubfx x3, x9, \shift, \fw
|
|
lsl x3, x3, \ls
|
|
mov x10, xzr
|
|
b do_dcsw_op
|
|
.endm
|
|
|
|
func do_dcsw_op
|
|
cbz x3, exit
|
|
adr x14, dcsw_loop_table // compute inner loop address
|
|
add x14, x14, x0, lsl #5 // inner loop is 8x32-bit instructions
|
|
mov x0, x9
|
|
mov w8, #1
|
|
loop1:
|
|
add x2, x10, x10, lsr #1 // work out 3x current cache level
|
|
lsr x1, x0, x2 // extract cache type bits from clidr
|
|
and x1, x1, #7 // mask the bits for current cache only
|
|
cmp x1, #2 // see what cache we have at this level
|
|
b.lt level_done // nothing to do if no cache or icache
|
|
|
|
msr csselr_el1, x10 // select current cache level in csselr
|
|
isb // isb to sych the new cssr&csidr
|
|
mrs x1, ccsidr_el1 // read the new ccsidr
|
|
and x2, x1, #7 // extract the length of the cache lines
|
|
add x2, x2, #4 // add 4 (line length offset)
|
|
ubfx x4, x1, #3, #10 // maximum way number
|
|
clz w5, w4 // bit position of way size increment
|
|
lsl w9, w4, w5 // w9 = aligned max way number
|
|
lsl w16, w8, w5 // w16 = way number loop decrement
|
|
orr w9, w10, w9 // w9 = combine way and cache number
|
|
ubfx w6, w1, #13, #15 // w6 = max set number
|
|
lsl w17, w8, w2 // w17 = set number loop decrement
|
|
dsb sy // barrier before we start this level
|
|
br x14 // jump to DC operation specific loop
|
|
|
|
.macro dcsw_loop _op
|
|
loop2_\_op:
|
|
lsl w7, w6, w2 // w7 = aligned max set number
|
|
|
|
loop3_\_op:
|
|
orr w11, w9, w7 // combine cache, way and set number
|
|
dc \_op, x11
|
|
subs w7, w7, w17 // decrement set number
|
|
b.ge loop3_\_op
|
|
|
|
subs x9, x9, x16 // decrement way number
|
|
b.ge loop2_\_op
|
|
|
|
b level_done
|
|
.endm
|
|
|
|
level_done:
|
|
add x10, x10, #2 // increment cache number
|
|
cmp x3, x10
|
|
b.gt loop1
|
|
msr csselr_el1, xzr // select cache level 0 in csselr
|
|
dsb sy // barrier to complete final cache operation
|
|
isb
|
|
exit:
|
|
ret
|
|
endfunc do_dcsw_op
|
|
|
|
dcsw_loop_table:
|
|
dcsw_loop isw
|
|
dcsw_loop cisw
|
|
dcsw_loop csw
|
|
|
|
|
|
func dcsw_op_louis
|
|
dcsw_op #LOUIS_SHIFT, #CLIDR_FIELD_WIDTH, #LEVEL_SHIFT
|
|
endfunc dcsw_op_louis
|
|
|
|
|
|
func dcsw_op_all
|
|
dcsw_op #LOC_SHIFT, #CLIDR_FIELD_WIDTH, #LEVEL_SHIFT
|
|
endfunc dcsw_op_all
|
|
|
|
/* ---------------------------------------------------------------
|
|
* Helper macro for data cache operations by set/way for the
|
|
* level specified
|
|
* ---------------------------------------------------------------
|
|
*/
|
|
.macro dcsw_op_level level
|
|
mrs x9, clidr_el1
|
|
mov x3, \level
|
|
sub x10, x3, #2
|
|
b do_dcsw_op
|
|
.endm
|
|
|
|
/* ---------------------------------------------------------------
|
|
* Data cache operations by set/way for level 1 cache
|
|
*
|
|
* The main function, do_dcsw_op requires:
|
|
* x0: The operation type (0-2), as defined in arch.h
|
|
* ---------------------------------------------------------------
|
|
*/
|
|
func dcsw_op_level1
|
|
dcsw_op_level #(1 << LEVEL_SHIFT)
|
|
endfunc dcsw_op_level1
|
|
|
|
/* ---------------------------------------------------------------
|
|
* Data cache operations by set/way for level 2 cache
|
|
*
|
|
* The main function, do_dcsw_op requires:
|
|
* x0: The operation type (0-2), as defined in arch.h
|
|
* ---------------------------------------------------------------
|
|
*/
|
|
func dcsw_op_level2
|
|
dcsw_op_level #(2 << LEVEL_SHIFT)
|
|
endfunc dcsw_op_level2
|
|
|
|
/* ---------------------------------------------------------------
|
|
* Data cache operations by set/way for level 3 cache
|
|
*
|
|
* The main function, do_dcsw_op requires:
|
|
* x0: The operation type (0-2), as defined in arch.h
|
|
* ---------------------------------------------------------------
|
|
*/
|
|
func dcsw_op_level3
|
|
dcsw_op_level #(3 << LEVEL_SHIFT)
|
|
endfunc dcsw_op_level3
|