mirror of
https://github.com/ARM-software/arm-trusted-firmware.git
synced 2025-08-15 17:07:04 +02:00
09d40e0e08
Enforce full include path for includes. Deprecate old paths.
The following folders inside include/lib have been left unchanged:
- include/lib/cpus/${ARCH}
- include/lib/el3_runtime/${ARCH}
The reason for this change is that having a global namespace for
includes isn't a good idea. It defeats one of the advantages of having
folders and it introduces problems that are sometimes subtle (because
you may not know the header you are actually including if there are two
of them).
For example, this patch had to be created because two headers were
called the same way: e0ea0928d5 ("Fix gpio includes of mt8173 platform
to avoid collision."). More recently, this patch has had similar
problems: 46f9b2c3a2 ("drivers: add tzc380 support").
This problem was introduced in commit 4ecca33988 ("Move include and
source files to logical locations"). At that time, there weren't too
many headers so it wasn't a real issue. However, time has shown that
this creates problems.
Platforms that want to preserve the way they include headers may add the
removed paths to PLAT_INCLUDES, but this is discouraged.
Change-Id: I39dc53ed98f9e297a5966e723d1936d6ccf2fc8f
Signed-off-by: Antonio Nino Diaz <antonio.ninodiaz@arm.com>
99 lines
2.2 KiB
ArmAsm
99 lines
2.2 KiB
ArmAsm
/*
|
|
* Copyright (c) 2016, ARM Limited and Contributors. All rights reserved.
|
|
*
|
|
* SPDX-License-Identifier: BSD-3-Clause
|
|
*/
|
|
#ifndef ROCKCHIP_PLAT_LD_S
|
|
#define ROCKCHIP_PLAT_LD_S
|
|
|
|
#include <lib/xlat_tables/xlat_tables_defs.h>
|
|
|
|
MEMORY {
|
|
SRAM (rwx): ORIGIN = SRAM_BASE, LENGTH = SRAM_SIZE
|
|
PMUSRAM (rwx): ORIGIN = PMUSRAM_BASE, LENGTH = PMUSRAM_RSIZE
|
|
}
|
|
|
|
SECTIONS
|
|
{
|
|
. = SRAM_BASE;
|
|
ASSERT(. == ALIGN(PAGE_SIZE),
|
|
"SRAM_BASE address is not aligned on a page boundary.")
|
|
|
|
/*
|
|
* The SRAM space allocation for RK3399
|
|
* ----------------
|
|
* | m0 code bin
|
|
* ----------------
|
|
* | sram text
|
|
* ----------------
|
|
* | sram data
|
|
* ----------------
|
|
*/
|
|
.incbin_sram : ALIGN(PAGE_SIZE) {
|
|
__sram_incbin_start = .;
|
|
*(.sram.incbin)
|
|
__sram_incbin_real_end = .;
|
|
. = ALIGN(PAGE_SIZE);
|
|
__sram_incbin_end = .;
|
|
} >SRAM
|
|
ASSERT((__sram_incbin_real_end - __sram_incbin_start) <=
|
|
SRAM_BIN_LIMIT, ".incbin_sram has exceeded its limit")
|
|
|
|
.text_sram : ALIGN(PAGE_SIZE) {
|
|
__bl31_sram_text_start = .;
|
|
*(.sram.text)
|
|
*(.sram.rodata)
|
|
__bl31_sram_text_real_end = .;
|
|
. = ALIGN(PAGE_SIZE);
|
|
__bl31_sram_text_end = .;
|
|
} >SRAM
|
|
ASSERT((__bl31_sram_text_real_end - __bl31_sram_text_start) <=
|
|
SRAM_TEXT_LIMIT, ".text_sram has exceeded its limit")
|
|
|
|
.data_sram : ALIGN(PAGE_SIZE) {
|
|
__bl31_sram_data_start = .;
|
|
*(.sram.data)
|
|
__bl31_sram_data_real_end = .;
|
|
. = ALIGN(PAGE_SIZE);
|
|
__bl31_sram_data_end = .;
|
|
} >SRAM
|
|
ASSERT((__bl31_sram_data_real_end - __bl31_sram_data_start) <=
|
|
SRAM_DATA_LIMIT, ".data_sram has exceeded its limit")
|
|
|
|
.stack_sram : ALIGN(PAGE_SIZE) {
|
|
__bl31_sram_stack_start = .;
|
|
. += PAGE_SIZE;
|
|
__bl31_sram_stack_end = .;
|
|
} >SRAM
|
|
|
|
. = PMUSRAM_BASE;
|
|
|
|
/*
|
|
* pmu_cpuson_entrypoint request address
|
|
* align 64K when resume, so put it in the
|
|
* start of pmusram
|
|
*/
|
|
.pmusram : {
|
|
ASSERT(. == ALIGN(64 * 1024),
|
|
".pmusram.entry request 64K aligned.");
|
|
*(.pmusram.entry)
|
|
|
|
__bl31_pmusram_text_start = .;
|
|
*(.pmusram.text)
|
|
*(.pmusram.rodata)
|
|
__bl31_pmusram_text_end = .;
|
|
|
|
/* M0 start address request 4K align */
|
|
. = ALIGN(4096);
|
|
__pmusram_incbin_start = .;
|
|
*(.pmusram.incbin)
|
|
__pmusram_incbin_end = .;
|
|
|
|
__bl31_pmusram_data_start = .;
|
|
*(.pmusram.data)
|
|
__bl31_pmusram_data_end = .;
|
|
} >PMUSRAM
|
|
}
|
|
|
|
#endif /* ROCKCHIP_PLAT_LD_S */
|